85faf5c0b7
GitHub repo moved from <https://github.com/nedbat/coveragepy> to <https://github.com/coveragepy/coveragepy>.
43 lines
1.6 KiB
Bash
43 lines
1.6 KiB
Bash
# Contributor: Frederic Wang <fred.wang@free.fr>
|
|
|
|
_realname=coverage
|
|
pkgbase=mingw-w64-python-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
|
|
pkgver=7.11.3
|
|
pkgrel=1
|
|
pkgdesc="Code coverage measurement for Python (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
msys2_references=(
|
|
'anitya: 3811'
|
|
'archlinux: python-coverage'
|
|
'gentoo: dev-python/coverage'
|
|
'purl: pkg:pypi/coverage'
|
|
)
|
|
msys2_repository_url='https://github.com/coveragepy/coveragepy'
|
|
msys2_changelog_url='https://github.com/coveragepy/coveragepy/blob/main/CHANGES.rst'
|
|
url='https://coverage.readthedocs.io/'
|
|
license=('spdx:Apache-2.0')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-python")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
|
|
"${MINGW_PACKAGE_PREFIX}-python-installer"
|
|
"${MINGW_PACKAGE_PREFIX}-python-setuptools"
|
|
"${MINGW_PACKAGE_PREFIX}-cc")
|
|
options=('!strip')
|
|
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
|
|
sha256sums=('0f59387f5e6edbbffec2281affb71cdc85e0776c1745150a3ab9b6c1d016106b')
|
|
|
|
build() {
|
|
cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
|
|
${MINGW_PREFIX}/bin/python -m build --wheel --skip-dependency-check --no-isolation
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
${MINGW_PREFIX}/bin/python -m installer --prefix=${MINGW_PREFIX} \
|
|
--destdir="${pkgdir}" dist/*.whl
|
|
|
|
install -Dm644 "LICENSE.txt" "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
|
|
}
|