Dirk Stolle
1d8af43e7d
* python-archinfo: update to 9.2.189
* python-jupyter_notebook: update to 7.5.1
* python-debugpy: update to 1.8.19
* python-filelock: update to 3.20.1
* python-comtypes: update to 1.4.14
* python-{boto3,botocore}: update to 1.42.11
48 lines
1.8 KiB
Bash
48 lines
1.8 KiB
Bash
# Maintainer: J. Peter Mugaas <jpmugaas@suddenlink.net>
|
|
|
|
_realname=filelock
|
|
pkgbase=mingw-w64-python-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
|
|
pkgver=3.20.1
|
|
pkgrel=1
|
|
pkgdesc="A platform independent file lock (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
msys2_references=(
|
|
'archlinux: python-filelock'
|
|
'gentoo: dev-python/filelock'
|
|
'purl: pkg:pypi/filelock'
|
|
)
|
|
msys2_repository_url='https://github.com/tox-dev/filelock'
|
|
url='https://py-filelock.readthedocs.io/'
|
|
msys2_changelog_url='https://py-filelock.readthedocs.io/en/latest/changelog.html'
|
|
license=('spdx:Unlicense')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-python")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
|
|
"${MINGW_PACKAGE_PREFIX}-python-installer"
|
|
"${MINGW_PACKAGE_PREFIX}-python-hatchling"
|
|
"${MINGW_PACKAGE_PREFIX}-python-hatch-vcs")
|
|
checkdepends=("${MINGW_PACKAGE_PREFIX}-python-pytest"
|
|
"${MINGW_PACKAGE_PREFIX}-python-pytest-timeout")
|
|
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
|
|
sha256sums=('b8360948b351b80f420878d8516519a2204b07aefcdcfd24912a5d33127f188c')
|
|
|
|
build() {
|
|
cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
|
|
${MINGW_PREFIX}/bin/python -m build --wheel --skip-dependency-check --no-isolation
|
|
}
|
|
|
|
check() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
PYTHONPATH=src ${MINGW_PREFIX}/bin/pytest tests || warning "Tests failed"
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
${MINGW_PREFIX}/bin/python -m installer --prefix=${MINGW_PREFIX} \
|
|
--destdir="${pkgdir}" dist/*.whl
|
|
|
|
install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
|
|
}
|