43 lines
1.8 KiB
Bash
43 lines
1.8 KiB
Bash
# Maintainer: Sarah Ottinger <schalaalexiazeal@gmail.com>
|
|
|
|
_realname=google-cloud-storage
|
|
pkgbase=mingw-w64-python-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
|
|
pkgver=3.4.1
|
|
pkgrel=1
|
|
pkgdesc='Google Cloud Storage API client library (mingw-w64)'
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url="https://github.com/googleapis/python-storage"
|
|
msys2_changelog_url='https://github.com/googleapis/python-storage/blob/main/CHANGELOG.md'
|
|
msys2_references=(
|
|
'aur: python-google-cloud-storage'
|
|
'purl: pkg:pypi/google-cloud-storage'
|
|
)
|
|
license=('spdx:Apache-2.0')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-python-google-auth"
|
|
"${MINGW_PACKAGE_PREFIX}-python-google-api-core"
|
|
"${MINGW_PACKAGE_PREFIX}-python-google-cloud-core"
|
|
"${MINGW_PACKAGE_PREFIX}-python-google-crc32c"
|
|
"${MINGW_PACKAGE_PREFIX}-python-google-resumable-media"
|
|
"${MINGW_PACKAGE_PREFIX}-python-requests")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
|
|
"${MINGW_PACKAGE_PREFIX}-python-installer"
|
|
"${MINGW_PACKAGE_PREFIX}-python-setuptools")
|
|
source=("https://pypi.org/packages/source/${_realname::1}/${_realname//-/_}/${_realname//-/_}-${pkgver}.tar.gz")
|
|
sha256sums=('6f041a297e23a4b485fad8c305a7a6e6831855c208bcbe74d00332a909f82268')
|
|
|
|
build() {
|
|
cp -r "${_realname//-/_}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
|
|
${MINGW_PREFIX}/bin/python -m build --wheel --skip-dependency-check --no-isolation
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
${MINGW_PREFIX}/bin/python -m installer --prefix=${MINGW_PREFIX} \
|
|
--destdir="${pkgdir}" dist/*.whl
|
|
|
|
install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
|
|
}
|