56 lines
2.1 KiB
Bash
56 lines
2.1 KiB
Bash
# Maintainer: Patrick Stewart <patstew@gmail.com>
|
|
|
|
_realname=jsonschema
|
|
pkgbase=mingw-w64-python-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
|
|
pkgver=4.25.1
|
|
pkgrel=1
|
|
pkgdesc="An implementation of JSON Schema validation for Python (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url="https://python-jsonschema.readthedocs.io/"
|
|
msys2_repository_url="https://github.com/python-jsonschema/jsonschema/"
|
|
msys2_changelog_url="https://github.com/python-jsonschema/jsonschema/blob/main/CHANGELOG.rst"
|
|
msys2_references=(
|
|
'archlinux: python-jsonschema'
|
|
'gentoo: dev-python/jsonschema'
|
|
'purl: pkg:pypi/jsonschema'
|
|
)
|
|
license=('spdx:MIT')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-python"
|
|
"${MINGW_PACKAGE_PREFIX}-python-attrs"
|
|
"${MINGW_PACKAGE_PREFIX}-python-jsonschema-specifications"
|
|
"${MINGW_PACKAGE_PREFIX}-python-rpds-py"
|
|
"${MINGW_PACKAGE_PREFIX}-python-referencing")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
|
|
"${MINGW_PACKAGE_PREFIX}-python-installer"
|
|
"${MINGW_PACKAGE_PREFIX}-python-hatchling"
|
|
"${MINGW_PACKAGE_PREFIX}-python-hatch-vcs"
|
|
"${MINGW_PACKAGE_PREFIX}-python-hatch-fancy-pypi-readme")
|
|
checkdepends=("${MINGW_PACKAGE_PREFIX}-python-pytest")
|
|
options=('!strip')
|
|
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
|
|
sha256sums=('e4a9655ce0da0c0b67a085847e00a3a51449e1157f4f75e9fb5aa545e122eb85')
|
|
|
|
build() {
|
|
cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
|
|
|
|
${MINGW_PREFIX}/bin/python -m build --wheel --skip-dependency-check --no-isolation
|
|
}
|
|
|
|
check() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
|
|
${MINGW_PREFIX}/bin/python -m pytest
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
|
|
MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
|
|
${MINGW_PREFIX}/bin/python -m installer --prefix=${MINGW_PREFIX} \
|
|
--destdir="${pkgdir}" dist/*.whl
|
|
|
|
install -Dm644 json/LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
|
|
}
|