49 lines
1.7 KiB
Bash
49 lines
1.7 KiB
Bash
# Maintainer: Alexey Pavlov <alexpux@gmail.com>
|
|
# Contributor: Konstantin Podsvirov <konstantin@podsvirov.pro>
|
|
|
|
_realname=asciidoc
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
|
|
conflicts=("${MINGW_PACKAGE_PREFIX}-asciidoc-py3-git")
|
|
provides=("${MINGW_PACKAGE_PREFIX}-asciidoc-py3-git")
|
|
pkgver=10.2.1
|
|
pkgrel=2
|
|
pkgdesc="AsciiDoc is a text document format for writing notes, documentation, articles, books, ebooks, slideshows, web pages, man pages and blogs (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url="https://github.com/asciidoc-py/asciidoc-py"
|
|
msys2_references=(
|
|
'pypi: asciidoc'
|
|
)
|
|
license=("GPL")
|
|
depends=("${MINGW_PACKAGE_PREFIX}-python"
|
|
"${MINGW_PACKAGE_PREFIX}-libxslt"
|
|
"${MINGW_PACKAGE_PREFIX}-docbook-xsl")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-python-setuptools" "${MINGW_PACKAGE_PREFIX}-cc")
|
|
source=(asciidoc-py-${pkgver}.tar.gz::${url}/archive/refs/tags/${pkgver}.tar.gz)
|
|
sha256sums=('8e1fb9691952cc4f13357e1ef58172e566c5f88e3c44222d4a8693585f884507')
|
|
|
|
prepare() {
|
|
cd "${srcdir}"
|
|
rm -rf "python-build-${MSYSTEM}" | true
|
|
cp -r "asciidoc-py-${pkgver}" "python-build-${MSYSTEM}"
|
|
}
|
|
|
|
build() {
|
|
msg "Python build for ${MSYSTEM}"
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
${MINGW_PREFIX}/bin/python setup.py build
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
|
|
${MINGW_PREFIX}/bin/python setup.py install --prefix=${MINGW_PREFIX} --root="${pkgdir}" -O1 --skip-build
|
|
|
|
for _f in "${pkgdir}${MINGW_PREFIX}"/bin/*-script.py; do
|
|
sed -e '1 { s/^#!.*$// }' -i ${_f}
|
|
done
|
|
|
|
install -Dm644 COPYRIGHT ${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYRIGHT
|
|
}
|