65 lines
2.5 KiB
Bash
65 lines
2.5 KiB
Bash
# Maintainer: Ray Donnelly <mingw.android@gmail.com>
|
|
# Based on Arch Linux package maintained by : Balló György <ballogyor+arch at gmail dot com>
|
|
|
|
_realname=d-feet
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
|
|
pkgver=0.3.16
|
|
pkgrel=6
|
|
pkgdesc="D-Bus debugger for GNOME (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url="https://wiki.gnome.org/Apps/DFeet"
|
|
license=('GPL')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-gtk3"
|
|
"${MINGW_PACKAGE_PREFIX}-python3-gobject"
|
|
"${MINGW_PACKAGE_PREFIX}-hicolor-icon-theme")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-python3-setuptools"
|
|
"${MINGW_PACKAGE_PREFIX}-gobject-introspection"
|
|
"${MINGW_PACKAGE_PREFIX}-meson"
|
|
"${MINGW_PACKAGE_PREFIX}-gtk-doc"
|
|
"${MINGW_PACKAGE_PREFIX}-pkgconf"
|
|
"${MINGW_PACKAGE_PREFIX}-itstool")
|
|
source=(https://download.gnome.org/sources/${_realname}/${pkgver%.*}/${_realname}-${pkgver}.tar.xz
|
|
001-make-reloc.patch
|
|
https://gitlab.gnome.org/GNOME/d-feet/-/commit/05465d486afdba116dbc22fc22c1e6573aea4f22.patch)
|
|
sha256sums=('8733ce4b9a9a54ec185b1d85bf4da9d9d11052882a880760ff60f9779b2d1ccb'
|
|
'5f4002b12ddf5c077976f4f20d1664070e9b36c9af0c28b0b89c994e29c59803'
|
|
'20d437bf23ec40916ee50fa905656be19614eb7297eaa4aef0e181dd03895178')
|
|
msys2_repository_url="https://gitlab.gnome.org/GNOME/d-feet"
|
|
|
|
prepare() {
|
|
cd "${srcdir}/${_realname}-${pkgver}"
|
|
|
|
patch -Np1 -i "${srcdir}"/001-make-reloc.patch
|
|
patch -Np1 -i "${srcdir}"/05465d486afdba116dbc22fc22c1e6573aea4f22.patch
|
|
}
|
|
|
|
build() {
|
|
[[ -d "${srcdir}/build-${CARCH}" ]] && rm -rf ${srcdir}/build-${CARCH}
|
|
mkdir -p ${srcdir}/build-${CARCH} && cd ${srcdir}/build-${CARCH}
|
|
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
${MINGW_PREFIX}/bin/meson \
|
|
--prefix=${MINGW_PREFIX} \
|
|
--buildtype=plain \
|
|
-Dtests=false \
|
|
-Dpython=${MINGW_PREFIX}/bin/python.exe \
|
|
"../${_realname}-${pkgver}"
|
|
|
|
${MINGW_PREFIX}/bin/ninja
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/build-${CARCH}"
|
|
DESTDIR="${pkgdir}" ${MINGW_PREFIX}/bin/ninja install
|
|
install -Dm0644 "${srcdir}/${_realname}-${pkgver}"/COPYING ${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING
|
|
|
|
MSYS2_ARG_CONV_EXCL="-p" python -m compileall \
|
|
-o 0 -o 1 -q -s"${pkgdir}" -p"/" "${pkgdir}${MINGW_PREFIX}/lib"
|
|
|
|
#fix so the correct interpretter is used
|
|
local PREFIX_WIN=$(cygpath -wm ${MINGW_PREFIX})
|
|
sed -e "s|${PREFIX_WIN}/bin/python.exe|${MINGW_PREFIX}/bin/python.exe|g" -i "${pkgdir}${MINGW_PREFIX}/bin/d-feet"
|
|
}
|