67 lines
2.3 KiB
Bash
67 lines
2.3 KiB
Bash
# Maintainer: Alexey Pavlov <alexpux@gmail.com>
|
|
|
|
_realname=partio
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
|
|
pkgver=1.17.1
|
|
pkgrel=2
|
|
pkgdesc="A library for particle IO and manipulation (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url="https://github.com/wdas/partio/"
|
|
license=("custom")
|
|
depends=("${MINGW_PACKAGE_PREFIX}-freeglut"
|
|
"${MINGW_PACKAGE_PREFIX}-zlib"
|
|
"${MINGW_PACKAGE_PREFIX}-gcc-libs"
|
|
"${MINGW_PACKAGE_PREFIX}-libwinpthread-git")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
|
|
"${MINGW_PACKAGE_PREFIX}-cmake"
|
|
"${MINGW_PACKAGE_PREFIX}-ninja"
|
|
"${MINGW_PACKAGE_PREFIX}-doxygen"
|
|
"${MINGW_PACKAGE_PREFIX}-pkgconf"
|
|
"${MINGW_PACKAGE_PREFIX}-graphviz"
|
|
"${MINGW_PACKAGE_PREFIX}-python"
|
|
"${MINGW_PACKAGE_PREFIX}-swig")
|
|
optdepends=("${MINGW_PACKAGE_PREFIX}-python: Python module for partio")
|
|
source=(https://github.com/wdas/partio/archive/v${pkgver}/${_realname}-${pkgver}.tar.gz
|
|
001-install-layout.patch
|
|
010-threads.patch)
|
|
sha256sums=('5d00fbfc55817acb310bcaf61212a78b2c602e08b839060dfee69570b4b82464'
|
|
'cb6eb13e787245aea0803e9fefc1f168fa9eb6ae8f34cbfacd457ced870cd163'
|
|
'b4bbd7b6d5b64f7d6b04f55515837e84976790e3dd92e4deb1c2f8fa3bfac94a')
|
|
|
|
prepare() {
|
|
cd ${srcdir}/${_realname}-${pkgver}
|
|
patch -p1 -i ${srcdir}/001-install-layout.patch
|
|
patch -p1 -i ${srcdir}/010-threads.patch
|
|
}
|
|
|
|
build() {
|
|
mkdir -p build-${MSYSTEM} && cd build-${MSYSTEM}
|
|
|
|
declare -a _extra_config
|
|
if check_option "debug" "n"; then
|
|
_extra_config+=("-DCMAKE_BUILD_TYPE=Release")
|
|
else
|
|
_extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
|
|
fi
|
|
|
|
MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
|
|
${MINGW_PREFIX}/bin/cmake.exe \
|
|
-G"Ninja" \
|
|
-DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \
|
|
-DPARTIO_BUILD_SHARED_LIBS=ON \
|
|
-DCMAKE_DLL_NAME_WITH_SOVERSION=ON \
|
|
"${_extra_config[@]}" \
|
|
../${_realname}-${pkgver}
|
|
|
|
${MINGW_PREFIX}/bin/cmake.exe --build ./
|
|
}
|
|
|
|
package() {
|
|
cd ${srcdir}/build-${MSYSTEM}
|
|
|
|
DESTDIR=${pkgdir} ${MINGW_PREFIX}/bin/cmake.exe --install ./
|
|
install -Dm644 "${srcdir}/${_realname}-${pkgver}/LICENSE" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
|
|
}
|