46 lines
1.6 KiB
Bash
46 lines
1.6 KiB
Bash
# Maintainer: Biswapriyo Nath <nathbappai@gmail.com>
|
|
|
|
_realname=rapidfuzz-cpp
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
|
|
pkgver=2.1.1
|
|
pkgrel=1
|
|
pkgdesc="Rapid fuzzy string matching in C++ using the Levenshtein Distance (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32' 'clangarm64')
|
|
url='https://maxbachmann.github.io/rapidfuzz-cpp/'
|
|
msys2_repository_url='https://github.com/maxbachmann/rapidfuzz-cpp/'
|
|
msys2_references=(
|
|
'archlinux: rapidfuzz-cpp'
|
|
)
|
|
license=('spdx:MIT')
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-cmake"
|
|
"${MINGW_PACKAGE_PREFIX}-ninja"
|
|
"${MINGW_PACKAGE_PREFIX}-cc")
|
|
source=("${_realname}-${pkgver}.tar.gz::https://github.com/maxbachmann/rapidfuzz-cpp/archive/refs/tags/v${pkgver}.tar.gz")
|
|
sha256sums=('1680c0dbf77d228ea81825c24755db99ee0e21a8db3663b5136741b3e108c3f2')
|
|
|
|
build() {
|
|
declare -a _extra_config
|
|
if check_option "debug" "n"; then
|
|
_extra_config+=("-DCMAKE_BUILD_TYPE=Release")
|
|
else
|
|
_extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
|
|
fi
|
|
|
|
MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
|
|
"${MINGW_PREFIX}"/bin/cmake.exe \
|
|
-GNinja \
|
|
-DCMAKE_INSTALL_PREFIX="${MINGW_PREFIX}" \
|
|
"${_extra_config[@]}" \
|
|
-S "${_realname}-${pkgver}" \
|
|
-B "build-${MSYSTEM}"
|
|
|
|
"${MINGW_PREFIX}"/bin/cmake.exe --build "build-${MSYSTEM}"
|
|
}
|
|
|
|
package() {
|
|
DESTDIR="${pkgdir}" "${MINGW_PREFIX}"/bin/cmake.exe --install "build-${MSYSTEM}"
|
|
install -Dm644 "${srcdir}/${_realname}-${pkgver}/LICENSE" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
|
|
}
|