1e7737f090
See https://github.com/msys2/MINGW-packages/pull/21998
and 89521b9f8d
This is the first batch of removals to start things off.
64 lines
2.0 KiB
Bash
64 lines
2.0 KiB
Bash
# Maintaner: Marty Plummer (The_NetZ) <ntzrmtthihu777 (at) gmail (dot) com>
|
|
# Contributor: Sven-Hendrik Haase <sh@lutzhaase.com>
|
|
|
|
_realname=SDL2_ttf
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname=${MINGW_PACKAGE_PREFIX}-${_realname}
|
|
pkgver=2.22.0
|
|
pkgrel=1
|
|
pkgdesc="A library that allows you to use TrueType fonts in your SDL applications (Version 2) (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url="https://github.com/libsdl-org/SDL_ttf"
|
|
msys2_references=(
|
|
"cpe: cpe:/a:libsdl:sdl_ttf"
|
|
)
|
|
license=('spdx:Zlib')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-SDL2"
|
|
"${MINGW_PACKAGE_PREFIX}-freetype"
|
|
"${MINGW_PACKAGE_PREFIX}-harfbuzz")
|
|
makedepends=(
|
|
"${MINGW_PACKAGE_PREFIX}-cmake"
|
|
"${MINGW_PACKAGE_PREFIX}-cc"
|
|
"${MINGW_PACKAGE_PREFIX}-autotools")
|
|
source=("https://github.com/libsdl-org/SDL_ttf/releases/download/release-${pkgver}/SDL2_ttf-${pkgver}.zip"{,.sig})
|
|
sha256sums=('5766070145111cb047807fa3f91c2c6b81bc1008d63817e100417959b42a2484'
|
|
'SKIP')
|
|
validpgpkeys=('1528635D8053A57F77D1E08630A59377A7763BE6') # Sam Lantinga <slouken@libsdl.org>
|
|
|
|
prepare() {
|
|
cd "${srcdir}/${_realname}-${pkgver}"
|
|
|
|
# Do not force generate to pacify libtool
|
|
autoreconf
|
|
}
|
|
|
|
build() {
|
|
mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
../${_realname}-${pkgver}/configure \
|
|
--prefix=${MINGW_PREFIX} \
|
|
--build=${MINGW_CHOST} \
|
|
--host=${MINGW_CHOST} \
|
|
--target=${MINGW_CHOST} \
|
|
--enable-shared \
|
|
--enable-static \
|
|
--disable-freetype-builtin \
|
|
--disable-harfbuzz-builtin
|
|
|
|
make
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/build-${MSYSTEM}"
|
|
make DESTDIR="${pkgdir}" install
|
|
|
|
local PREFIX_WIN=$(cygpath -wm ${MINGW_PREFIX})
|
|
for _f in "${pkgdir}${MINGW_PREFIX}"/lib/cmake/${_realname}/*.cmake; do
|
|
sed -e "s|${PREFIX_WIN}|\$\{_IMPORT_PREFIX\}|g" -i ${_f}
|
|
sed -e "s|${MINGW_PREFIX}|\$\{_IMPORT_PREFIX\}|g" -i ${_f}
|
|
done
|
|
|
|
install -Dm644 ${srcdir}/${_realname}-${pkgver}/LICENSE.txt "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE.txt"
|
|
}
|