58 lines
1.7 KiB
Bash
58 lines
1.7 KiB
Bash
# Maintainer: Konstantin Podsvirov <konstantin@podsvirov.su>
|
|
|
|
_realname=cargo-local-registry
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
|
|
pkgver=0.2.8
|
|
pkgrel=1
|
|
pkgdesc="A cargo subcommand to manage local registries (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url="https://github.com/dhovart/cargo-local-registry"
|
|
msys2_references=(
|
|
'aur: cargo-local-registry'
|
|
'purl: pkg:cargo/cargo-local-registry'
|
|
)
|
|
license=('spdx:MIT OR Apache-2.0')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-zlib"
|
|
"${MINGW_PACKAGE_PREFIX}-libssh2")
|
|
#"${MINGW_PACKAGE_PREFIX}-libgit2")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-rust"
|
|
"${MINGW_PACKAGE_PREFIX}-pkgconf"
|
|
"${MINGW_PACKAGE_PREFIX}-openssl")
|
|
source=("${url}/archive/v${pkgver}/${_realname}-${pkgver}.tar.gz")
|
|
sha256sums=('7247741a99736b321a015fe4979482842b30f0923325435a48063593c3027751')
|
|
|
|
prepare() {
|
|
cd "${_realname}-${pkgver}"
|
|
|
|
# not compatible with libgit2 1.9+
|
|
# export LIBGIT2_NO_VENDOR=1
|
|
export OPENSSL_NO_VENDOR=1
|
|
export LIBSSH2_SYS_USE_PKG_CONFIG=1
|
|
|
|
cargo update -p cc
|
|
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
|
|
}
|
|
|
|
build() {
|
|
cd "${_realname}-${pkgver}"
|
|
|
|
cargo build --release --frozen
|
|
}
|
|
|
|
check() {
|
|
cd "${_realname}-${pkgver}"
|
|
|
|
cargo test --release --frozen
|
|
}
|
|
|
|
package() {
|
|
cd "${_realname}-${pkgver}"
|
|
|
|
install -Dm755 "target/release/${_realname}.exe" "${pkgdir}${MINGW_PREFIX}/bin/${_realname}.exe"
|
|
install -Dm644 "README.md" "${pkgdir}${MINGW_PREFIX}/share/doc/${_realname}/README.md"
|
|
install -Dm644 "LICENSE-MIT" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE-MIT"
|
|
install -Dm644 "LICENSE-APACHE" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE-APACHE"
|
|
}
|