58 lines
1.7 KiB
Bash
58 lines
1.7 KiB
Bash
# Maintainer: J. Peter Mugaas <jpmugaas@suddenlink.net>
|
|
|
|
_realname=libraqm
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
|
|
pkgver=0.10.3
|
|
pkgrel=1
|
|
pkgdesc="A library that encapsulates the logic for complex text layout (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url="https://github.com/HOST-Oman/libraqm"
|
|
msys2_repository_url=${url}
|
|
msys2_references=(
|
|
'purl: pkg:github/host-oman/libraqm'
|
|
)
|
|
license=('spdx:MIT')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-freetype"
|
|
"${MINGW_PACKAGE_PREFIX}-harfbuzz"
|
|
"${MINGW_PACKAGE_PREFIX}-fribidi")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
|
|
"${MINGW_PACKAGE_PREFIX}-meson"
|
|
"${MINGW_PACKAGE_PREFIX}-pkgconf"
|
|
"${MINGW_PACKAGE_PREFIX}-gtk-doc")
|
|
source=("${msys2_repository_url}/archive/v${pkgver}/${_realname}-${pkgver}.tar.gz")
|
|
sha256sums=('fe1fe28b32f97ef97b325ca5d2defb0704da1ef048372ec20e85e1f587e20965')
|
|
|
|
build() {
|
|
declare -a extra_config
|
|
if check_option "debug" "n"; then
|
|
extra_config+=("--buildtype=release")
|
|
else
|
|
extra_config+=("--buildtype=debug")
|
|
fi
|
|
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
meson setup \
|
|
--prefix="${MINGW_PREFIX}" \
|
|
"${extra_config[@]}" \
|
|
--wrap-mode=nodownload \
|
|
--default-library=both \
|
|
--auto-features=enabled \
|
|
-Ddocs=true \
|
|
"build-${MSYSTEM}" \
|
|
"${_realname}-${pkgver}"
|
|
|
|
meson compile -C "build-${MSYSTEM}"
|
|
}
|
|
|
|
check() {
|
|
meson test -C "build-${MSYSTEM}"
|
|
}
|
|
|
|
package() {
|
|
meson install -C "build-${MSYSTEM}" --destdir "${pkgdir}"
|
|
install -Dm644 "${srcdir}"/${_realname}-${pkgver}/COPYING \
|
|
"${pkgdir}"${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE
|
|
}
|