68 lines
2.7 KiB
Bash
68 lines
2.7 KiB
Bash
# Maintainer: Kyle Kauffman <kyle.j.kauffman@gmail.com>
|
|
|
|
_realname=ipython
|
|
pkgbase=mingw-w64-python-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
|
|
provides=("${MINGW_PACKAGE_PREFIX}-python3-${_realname}")
|
|
conflicts=("${MINGW_PACKAGE_PREFIX}-python3-${_realname}")
|
|
replaces=("${MINGW_PACKAGE_PREFIX}-python3-${_realname}")
|
|
pkgver=8.11.0
|
|
pkgrel=1
|
|
pkgdesc="An enhanced Interactive Python shell (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32' 'clangarm64')
|
|
url="https://ipython.org/"
|
|
license=('BSD')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-python-backcall"
|
|
"${MINGW_PACKAGE_PREFIX}-python-colorama"
|
|
"${MINGW_PACKAGE_PREFIX}-python-decorator"
|
|
"${MINGW_PACKAGE_PREFIX}-python-jedi"
|
|
"${MINGW_PACKAGE_PREFIX}-python-matplotlib-inline"
|
|
"${MINGW_PACKAGE_PREFIX}-python-pickleshare"
|
|
"${MINGW_PACKAGE_PREFIX}-python-prompt_toolkit"
|
|
"${MINGW_PACKAGE_PREFIX}-python-pygments"
|
|
"${MINGW_PACKAGE_PREFIX}-python-stack-data"
|
|
"${MINGW_PACKAGE_PREFIX}-python-traitlets"
|
|
"winpty")
|
|
optdepends=("${MINGW_PACKAGE_PREFIX}-python-qtconsole: for ipython qtconsole"
|
|
"${MINGW_PACKAGE_PREFIX}-python-ipython-ipyparallel: for IPython.parallel")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
|
|
"${MINGW_PACKAGE_PREFIX}-python-installer"
|
|
"${MINGW_PACKAGE_PREFIX}-python-setuptools"
|
|
"${MINGW_PACKAGE_PREFIX}-python-wheel")
|
|
checkdepends=("${MINGW_PACKAGE_PREFIX}-python-requests"
|
|
"${MINGW_PACKAGE_PREFIX}-python-testpath"
|
|
"${MINGW_PACKAGE_PREFIX}-python-pygments"
|
|
"${MINGW_PACKAGE_PREFIX}-python-jupyter-nbformat"
|
|
"${MINGW_PACKAGE_PREFIX}-python-ipykernel"
|
|
"${MINGW_PACKAGE_PREFIX}-python-numpy")
|
|
options=('!strip')
|
|
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
|
|
sha256sums=('735cede4099dbc903ee540307b9171fbfef4aa75cfcacc5a273b2cda2f02be04')
|
|
|
|
prepare() {
|
|
cd "${srcdir}"
|
|
rm -rf python-build-${MSYSTEM} | true
|
|
cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}"
|
|
}
|
|
|
|
build() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
${MINGW_PREFIX}/bin/python -m build --wheel --skip-dependency-check --no-isolation
|
|
}
|
|
|
|
check() {
|
|
msg "Python test for ${MSYSTEM}"
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
${MINGW_PREFIX}/bin/python -m pytest || warning "Tests fail"
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
${MINGW_PREFIX}/bin/python -m installer --prefix=${MINGW_PREFIX} \
|
|
--destdir="${pkgdir}" dist/*.whl
|
|
|
|
install -Dm644 docs/source/about/license_and_copyright.rst "${pkgdir}${MINGW_PREFIX}/share/licenses/python-ipython/LICENSE"
|
|
}
|