9757046077
* python3: Update to 3.6.1
The patches starting with 16 are new to fix the build.
Some no longer relevant patches were dropped, the rest is just refreshed.
* Bump pkgrel of all packages containing Python 3 bytecode/extensions.
The package list was generated using:
pkgfile.exe -R mingw64 -r "cpython.*\\.(py[cod]|dll)"
* lensfun: Add cmake to makedepends
* numpy: Don't hardcode the Python version
* blender: rebuild for new Python
* boost: Don't hardcode Python versions; rebuild
* pillow: Don't hardcode Python version; rebuild
* python-dateutil: Don't hardcode Python versions
* sip: Don't hardcode Python versions
* pyqt4: Don't hardcode Python versions; rebuild
* pyqt5: Don't hardcode Python versions; rebuild
* opencv: Update Python3 version in patch
140 lines
5.0 KiB
Bash
140 lines
5.0 KiB
Bash
# Contributor: Runar Tenfjord < runar dot tenfjord at gmail dot com >
|
|
|
|
_realname=matplotlib
|
|
pkgbase=mingw-w64-python-${_realname}
|
|
pkgname=(
|
|
"${MINGW_PACKAGE_PREFIX}-python2-${_realname}"
|
|
"${MINGW_PACKAGE_PREFIX}-python3-${_realname}"
|
|
)
|
|
pkgver=2.0.0
|
|
pkgrel=2
|
|
pkgdesc="A python plotting library, making publication quality plots (mingw-w64)"
|
|
arch=('any')
|
|
url='http://matplotlib.org'
|
|
license=('custom')
|
|
makedepends=(
|
|
"${MINGW_PACKAGE_PREFIX}-python2-pytz"
|
|
"${MINGW_PACKAGE_PREFIX}-python3-pytz"
|
|
"${MINGW_PACKAGE_PREFIX}-python2-numpy"
|
|
"${MINGW_PACKAGE_PREFIX}-python3-numpy"
|
|
"${MINGW_PACKAGE_PREFIX}-python2-cairo"
|
|
"${MINGW_PACKAGE_PREFIX}-python3-cairo"
|
|
"${MINGW_PACKAGE_PREFIX}-python2-pyqt5"
|
|
"${MINGW_PACKAGE_PREFIX}-python3-pyqt5"
|
|
"${MINGW_PACKAGE_PREFIX}-python2-dateutil"
|
|
"${MINGW_PACKAGE_PREFIX}-python3-dateutil"
|
|
"${MINGW_PACKAGE_PREFIX}-python2-pyparsing"
|
|
"${MINGW_PACKAGE_PREFIX}-python3-pyparsing"
|
|
"${MINGW_PACKAGE_PREFIX}-python2-cycler"
|
|
"${MINGW_PACKAGE_PREFIX}-python3-cycler"
|
|
"${MINGW_PACKAGE_PREFIX}-freetype"
|
|
"${MINGW_PACKAGE_PREFIX}-libpng"
|
|
#"${MINGW_PACKAGE_PREFIX}-qhull"
|
|
)
|
|
source=(
|
|
"${_realname}-${pkgver}.tar.gz"::"https://github.com/matplotlib/matplotlib/archive/v${pkgver}.tar.gz"
|
|
setupext.py.patch
|
|
setup.py.patch
|
|
)
|
|
sha256sums=('966a0807bc961726a68e5b60b6e97c91eed6ba20e0d50dfd699a8f854b2d7370'
|
|
'76bd90000ed3c2b77db97db4fdf7e84a4c5e34e966f1a4feb6c91635df5c10ff'
|
|
'8d5128f3d1bc467832ec382456541f4aa32959a88d36ee33dc88d9035416017e')
|
|
noextract=("${_realname}-${pkgver}.tar.gz")
|
|
|
|
prepare() {
|
|
# Clean up old sources so re-patching doesn't fail.
|
|
[[ -d ${srcdir}/${_realname}-${pkgver} ]] && rm -rf $srcdir/${_realname}-${pkgver}
|
|
tar -xzvf ${_realname}-${pkgver}.tar.gz -C ${srcdir}
|
|
|
|
cd ${srcdir}/${_realname}-${pkgver}
|
|
patch -p1 -i ${srcdir}/setupext.py.patch
|
|
patch -p1 -i ${srcdir}/setup.py.patch
|
|
cd ${srcdir}
|
|
|
|
cp -a ${_realname}-${pkgver} ${_realname}-py2-${pkgver}
|
|
cp -a ${_realname}-${pkgver} ${_realname}-py3-${pkgver}
|
|
|
|
cd ${srcdir}/${_realname}-py3-${pkgver}
|
|
# remove cairo which fails for python3
|
|
sed -i 's/setupext\.BackendGtk3Cairo/#setupext\.BackendGtk3Cairo/g' setup.py
|
|
sed -i 's/setupext\.BackendCairo/#setupext\.BackendCairo/g' setup.py
|
|
|
|
cd ${srcdir}/${_realname}-py2-${pkgver}
|
|
sed -e "s|#![ ]*/usr/bin/python$|#!/usr/bin/env python2|" \
|
|
-e "s|#![ ]*/usr/bin/env python$|#!/usr/bin/env python2|" \
|
|
-e "s|#![ ]*/bin/env python$|#!/usr/bin/env python2|" \
|
|
-i $(find . -name '*.py')
|
|
}
|
|
|
|
build() {
|
|
cd ${srcdir}/${_realname}-py2-${pkgver}
|
|
MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
|
|
${MINGW_PREFIX}/bin/python2 setup.py build
|
|
|
|
cd ${srcdir}/${_realname}-py3-${pkgver}
|
|
MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
|
|
${MINGW_PREFIX}/bin/python3 setup.py build
|
|
}
|
|
|
|
package_python3-matplotlib() {
|
|
depends=(
|
|
"${MINGW_PACKAGE_PREFIX}-python3-pytz"
|
|
"${MINGW_PACKAGE_PREFIX}-python3-numpy"
|
|
"${MINGW_PACKAGE_PREFIX}-python3-cairo"
|
|
"${MINGW_PACKAGE_PREFIX}-python3-cycler"
|
|
"${MINGW_PACKAGE_PREFIX}-python3-pyqt5"
|
|
"${MINGW_PACKAGE_PREFIX}-python3-dateutil"
|
|
"${MINGW_PACKAGE_PREFIX}-python3-pyparsing"
|
|
"${MINGW_PACKAGE_PREFIX}-freetype"
|
|
"${MINGW_PACKAGE_PREFIX}-libpng"
|
|
#"${MINGW_PACKAGE_PREFIX}-qhull"
|
|
)
|
|
cd ${srcdir}/${_realname}-py3-${pkgver}
|
|
|
|
MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
|
|
${MINGW_PREFIX}/bin/python3 setup.py install -O1 --skip-build \
|
|
--root="${pkgdir}" --prefix=${MINGW_PREFIX}
|
|
|
|
install -Dm644 doc/users/license.rst "${pkgdir}${MINGW_PREFIX}"/share/licenses/python3-matplotlib/LICENSE
|
|
}
|
|
|
|
package_python2-matplotlib() {
|
|
depends=(
|
|
"${MINGW_PACKAGE_PREFIX}-python2-pytz"
|
|
"${MINGW_PACKAGE_PREFIX}-python2-numpy"
|
|
"${MINGW_PACKAGE_PREFIX}-python2-cairo"
|
|
"${MINGW_PACKAGE_PREFIX}-python2-cycler"
|
|
"${MINGW_PACKAGE_PREFIX}-python2-pyqt5"
|
|
"${MINGW_PACKAGE_PREFIX}-python2-dateutil"
|
|
"${MINGW_PACKAGE_PREFIX}-python2-pyparsing"
|
|
"${MINGW_PACKAGE_PREFIX}-freetype"
|
|
"${MINGW_PACKAGE_PREFIX}-libpng"
|
|
#"${MINGW_PACKAGE_PREFIX}-qhull"
|
|
)
|
|
cd ${srcdir}/${_realname}-py2-${pkgver}
|
|
|
|
MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
|
|
${MINGW_PREFIX}/bin/python2 setup.py install -O1 --skip-build \
|
|
--root="${pkgdir}" --prefix=${MINGW_PREFIX}
|
|
|
|
install -Dm644 doc/users/license.rst "${pkgdir}${MINGW_PREFIX}"/share/licenses/python2-matplotlib/LICENSE
|
|
}
|
|
|
|
package_mingw-w64-i686-python2-matplotlib() {
|
|
package_python2-matplotlib
|
|
}
|
|
|
|
package_mingw-w64-i686-python3-matplotlib() {
|
|
package_python3-matplotlib
|
|
}
|
|
|
|
package_mingw-w64-x86_64-python2-matplotlib() {
|
|
package_python2-matplotlib
|
|
}
|
|
|
|
package_mingw-w64-x86_64-python3-matplotlib() {
|
|
package_python3-matplotlib
|
|
}
|
|
|
|
# vim:set ts=2 sw=2 et:
|