55 lines
1.8 KiB
Bash
55 lines
1.8 KiB
Bash
# Maintainer: Biswapriyo Nath <nathbappai@gmail.com>
|
|
|
|
_realname=mysqlclient
|
|
pkgbase=mingw-w64-python-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
|
|
pkgver=2.2.0
|
|
pkgrel=1
|
|
pkgdesc="Fork of MySQL-python with support for Python 3 (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32')
|
|
msys2_repository_url='https://github.com/PyMySQL/mysqlclient-python'
|
|
msys2_references=(
|
|
'pypi: mysqlclient'
|
|
)
|
|
url='https://mysqlclient.readthedocs.io/'
|
|
license=('spdx:GPL-2.0-or-later')
|
|
depends=(
|
|
"${MINGW_PACKAGE_PREFIX}-python"
|
|
)
|
|
makedepends=(
|
|
"${MINGW_PACKAGE_PREFIX}-cc"
|
|
"${MINGW_PACKAGE_PREFIX}-libmariadbclient"
|
|
"${MINGW_PACKAGE_PREFIX}-python-build"
|
|
"${MINGW_PACKAGE_PREFIX}-python-installer"
|
|
"${MINGW_PACKAGE_PREFIX}-python-setuptools"
|
|
"${MINGW_PACKAGE_PREFIX}-python-wheel"
|
|
)
|
|
options=('!strip')
|
|
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz"
|
|
0001-mysqlclient-setup-fix-linking.patch)
|
|
sha256sums=('04368445f9c487d8abb7a878e3d23e923e6072c04a6c320f9e0dc8a82efba14e'
|
|
'0ea7aad43e7716edd538b076ea1e83db3889f32930943309284a61bc94fdf68a')
|
|
|
|
prepare() {
|
|
cd "${srcdir}/${_realname}-${pkgver}"
|
|
patch -p1 -i "${srcdir}/0001-mysqlclient-setup-fix-linking.patch"
|
|
}
|
|
|
|
build() {
|
|
cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
|
|
|
|
MYSQLCLIENT_CONNECTOR="${MINGW_PREFIX}" \
|
|
${MINGW_PREFIX}/bin/python -m build --wheel --skip-dependency-check --no-isolation
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
${MINGW_PREFIX}/bin/python -m installer --prefix=${MINGW_PREFIX} \
|
|
--destdir="${pkgdir}" dist/*.whl
|
|
|
|
install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
|
|
}
|