92 lines
2.9 KiB
Bash
92 lines
2.9 KiB
Bash
# Maintainer: Biswapriyo Nath <nathbappai@gmail.com>
|
|
|
|
_realname=libgedit-gtksourceview
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
|
|
pkgver=299.5.0
|
|
pkgrel=3
|
|
pkgdesc="A source code editing widget (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url='https://gedit-technology.github.io/'
|
|
msys2_repository_url='https://gitlab.gnome.org/World/gedit/libgedit-gtksourceview/'
|
|
msys2_documentation_url='https://gedit-technology.github.io/developer-docs/'
|
|
msys2_references=(
|
|
'archlinux: libgedit-gtksourceview'
|
|
)
|
|
license=('spdx:LGPL-2.1-or-later')
|
|
depends=(
|
|
"${MINGW_PACKAGE_PREFIX}-cairo"
|
|
"${MINGW_PACKAGE_PREFIX}-gdk-pixbuf2"
|
|
"${MINGW_PACKAGE_PREFIX}-gettext-runtime"
|
|
"${MINGW_PACKAGE_PREFIX}-glib2"
|
|
"${MINGW_PACKAGE_PREFIX}-gtk3"
|
|
"${MINGW_PACKAGE_PREFIX}-libxml2"
|
|
"${MINGW_PACKAGE_PREFIX}-pango"
|
|
)
|
|
makedepends=(
|
|
"${MINGW_PACKAGE_PREFIX}-cc"
|
|
"${MINGW_PACKAGE_PREFIX}-gettext-tools"
|
|
"${MINGW_PACKAGE_PREFIX}-gobject-introspection"
|
|
"${MINGW_PACKAGE_PREFIX}-gtk-doc"
|
|
"${MINGW_PACKAGE_PREFIX}-meson"
|
|
"${MINGW_PACKAGE_PREFIX}-ninja"
|
|
"${MINGW_PACKAGE_PREFIX}-pkgconf"
|
|
)
|
|
source=("https://gitlab.gnome.org/World/gedit/libgedit-gtksourceview/-/archive/${pkgver}/${_realname}-${pkgver}.tar.gz")
|
|
sha256sums=('49b66fe7e2d33dbf643107ae16fe324edf91bb21e86a927b2c5981f63f4cbb12')
|
|
|
|
build() {
|
|
local -a _static_flags=(
|
|
-DCAIRO_WIN32_STATIC_BUILD
|
|
-DGIO_STATIC_COMPILATION
|
|
-DGLIB_STATIC_COMPILATION
|
|
-DGMODULE_STATIC_COMPILATION
|
|
-DGOBJECT_STATIC_COMPILATION
|
|
-DLIBXML_STATIC
|
|
)
|
|
|
|
local -a _meson_options=(
|
|
--prefix="${MINGW_PREFIX}"
|
|
--wrap-mode=nodownload
|
|
--auto-features=enabled
|
|
--buildtype=plain
|
|
)
|
|
|
|
CFLAGS+=" ${_static_flags[@]}" \
|
|
CXXFLAGS+=" ${_static_flags[@]}" \
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
${MINGW_PREFIX}/bin/meson.exe setup \
|
|
"${_meson_options[@]}" \
|
|
--default-library=static \
|
|
-Dgtk_doc=false \
|
|
-Dgobject_introspection=false \
|
|
"${_realname}-${pkgver}" \
|
|
"build-${MSYSTEM}-static"
|
|
|
|
${MINGW_PREFIX}/bin/meson.exe compile -C "build-${MSYSTEM}-static"
|
|
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
${MINGW_PREFIX}/bin/meson.exe setup \
|
|
"${_meson_options[@]}" \
|
|
--default-library=shared \
|
|
-Dgtk_doc=true \
|
|
-Dgobject_introspection=true \
|
|
"${_realname}-${pkgver}" \
|
|
"build-${MSYSTEM}-shared"
|
|
|
|
${MINGW_PREFIX}/bin/meson.exe compile -C "build-${MSYSTEM}-shared"
|
|
}
|
|
|
|
check() {
|
|
${MINGW_PREFIX}/bin/meson.exe test -C "build-${MSYSTEM}-static" || warning "Tests failed"
|
|
${MINGW_PREFIX}/bin/meson.exe test -C "build-${MSYSTEM}-shared" || warning "Tests failed"
|
|
}
|
|
|
|
package() {
|
|
${MINGW_PREFIX}/bin/meson.exe install -C "build-${MSYSTEM}-static" --destdir "${pkgdir}"
|
|
${MINGW_PREFIX}/bin/meson.exe install -C "build-${MSYSTEM}-shared" --destdir "${pkgdir}"
|
|
|
|
install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING"
|
|
}
|