715895ab3b
* gstreamer: Update to 1.26.7 * gst-plugins-base: Update to 1.26.7 * gst-plugins-good: Update to 1.26.7 * gst-plugins-bad: Update to 1.26.7 * gst-plugins-ugly: Update to 1.26.7 * gst-libav: Update to 1.26.7 * gst-editing-services: Update to 1.26.7 * gst-rtsp-server: Update to 1.26.7 * gst-python: Update to 1.26.7 * gst-devtools: Update to 1.26.7 * gst-plugins-rs: Update to 1.26.7
64 lines
2.1 KiB
Bash
64 lines
2.1 KiB
Bash
# Maintainer: AlexWMF <alexxwmf@gmail.com>
|
|
|
|
_realname=gst-plugins-ugly
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
|
|
pkgver=1.26.7
|
|
pkgrel=1
|
|
pkgdesc="GStreamer Multimedia Framework Ugly Plugins (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url="https://gstreamer.freedesktop.org/"
|
|
msys2_references=(
|
|
"cpe: cpe:2.3:a:gstreamer:gstreamer"
|
|
"cpe: cpe:2.3:a:gstreamer_project:gstreamer"
|
|
)
|
|
license=("spdx:LGPL-2.1-or-later")
|
|
depends=("${MINGW_PACKAGE_PREFIX}-a52dec"
|
|
"${MINGW_PACKAGE_PREFIX}-gettext-runtime"
|
|
"${MINGW_PACKAGE_PREFIX}-glib2"
|
|
"${MINGW_PACKAGE_PREFIX}-gst-plugins-base"
|
|
"${MINGW_PACKAGE_PREFIX}-gstreamer"
|
|
"${MINGW_PACKAGE_PREFIX}-libcdio"
|
|
"${MINGW_PACKAGE_PREFIX}-libdvdread"
|
|
"${MINGW_PACKAGE_PREFIX}-libmpeg2"
|
|
"${MINGW_PACKAGE_PREFIX}-libx264")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
|
|
"${MINGW_PACKAGE_PREFIX}-meson"
|
|
"${MINGW_PACKAGE_PREFIX}-pkgconf"
|
|
"${MINGW_PACKAGE_PREFIX}-ninja"
|
|
"${MINGW_PACKAGE_PREFIX}-gobject-introspection"
|
|
"${MINGW_PACKAGE_PREFIX}-gtk-doc"
|
|
"${MINGW_PACKAGE_PREFIX}-libcdio>=2.1.0-2")
|
|
source=("${url}/src/${_realname}/${_realname}-${pkgver}.tar.xz"{,.asc})
|
|
sha256sums=('11f2e4f34bb2e841dc60edc95581572bc47be0c11e577d12bed98bb1f80a661b'
|
|
'SKIP')
|
|
validpgpkeys=('D637032E45B8C6585B9456565D2EEE6F6F349D7C') # Tim Müller <tim@gstreamer-foundation.org>
|
|
|
|
build() {
|
|
mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
${MINGW_PREFIX}/bin/meson.exe setup \
|
|
--prefix="${MINGW_PREFIX}" \
|
|
--buildtype plain \
|
|
--wrap-mode=nofallback \
|
|
-Dauto_features=enabled \
|
|
-Dpackage-origin='https://www.msys2.org' \
|
|
-Dtests=disabled \
|
|
-Dsidplay=disabled \
|
|
-Ddoc=disabled \
|
|
-Dgpl=enabled \
|
|
../${_realname}-${pkgver}
|
|
|
|
${MINGW_PREFIX}/bin/meson.exe compile
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
DESTDIR="${pkgdir}" ${MINGW_PREFIX}/bin/meson.exe install
|
|
|
|
rm -f "${pkgdir}"${MINGW_PREFIX}/lib/gstreamer*/*.a
|
|
}
|