93 lines
3.4 KiB
Bash
93 lines
3.4 KiB
Bash
# Maintainer: Peter Budai <peterbud@hotmail.com>
|
|
|
|
_realname=darktable
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
|
|
pkgver=5.2.1
|
|
pkgrel=4
|
|
pkgdesc="darktable is an open source photography workflow application and raw developer (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url='https://www.darktable.org/'
|
|
msys2_repository_url='https://github.com/darktable-org/darktable'
|
|
license=('spdx:GPL-3.0-or-later')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-curl"
|
|
"${MINGW_PACKAGE_PREFIX}-drmingw"
|
|
"${MINGW_PACKAGE_PREFIX}-exiv2"
|
|
"${MINGW_PACKAGE_PREFIX}-cc-libs"
|
|
"${MINGW_PACKAGE_PREFIX}-gettext-runtime"
|
|
"${MINGW_PACKAGE_PREFIX}-gmic"
|
|
"${MINGW_PACKAGE_PREFIX}-graphicsmagick"
|
|
"${MINGW_PACKAGE_PREFIX}-gtk3"
|
|
"${MINGW_PACKAGE_PREFIX}-icu"
|
|
"${MINGW_PACKAGE_PREFIX}-imath"
|
|
"${MINGW_PACKAGE_PREFIX}-iso-codes"
|
|
"${MINGW_PACKAGE_PREFIX}-lcms2"
|
|
"${MINGW_PACKAGE_PREFIX}-lensfun"
|
|
"${MINGW_PACKAGE_PREFIX}-libavif"
|
|
"${MINGW_PACKAGE_PREFIX}-libgphoto2"
|
|
"${MINGW_PACKAGE_PREFIX}-libheif"
|
|
"${MINGW_PACKAGE_PREFIX}-libjpeg-turbo"
|
|
"${MINGW_PACKAGE_PREFIX}-libjxl"
|
|
"${MINGW_PACKAGE_PREFIX}-libpng"
|
|
"${MINGW_PACKAGE_PREFIX}-libraw"
|
|
"${MINGW_PACKAGE_PREFIX}-librsvg"
|
|
"${MINGW_PACKAGE_PREFIX}-libsecret"
|
|
"${MINGW_PACKAGE_PREFIX}-libtiff"
|
|
"${MINGW_PACKAGE_PREFIX}-libwebp"
|
|
"${MINGW_PACKAGE_PREFIX}-libxml2"
|
|
"${MINGW_PACKAGE_PREFIX}-lua"
|
|
"${MINGW_PACKAGE_PREFIX}-omp"
|
|
"${MINGW_PACKAGE_PREFIX}-openexr"
|
|
"${MINGW_PACKAGE_PREFIX}-openjpeg2"
|
|
"${MINGW_PACKAGE_PREFIX}-osm-gps-map"
|
|
"${MINGW_PACKAGE_PREFIX}-portmidi"
|
|
"${MINGW_PACKAGE_PREFIX}-pugixml"
|
|
"${MINGW_PACKAGE_PREFIX}-SDL2"
|
|
"${MINGW_PACKAGE_PREFIX}-sqlite3"
|
|
"${MINGW_PACKAGE_PREFIX}-zlib")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
|
|
"${MINGW_PACKAGE_PREFIX}-cmake"
|
|
"${MINGW_PACKAGE_PREFIX}-ninja"
|
|
"${MINGW_PACKAGE_PREFIX}-libxslt"
|
|
"${MINGW_PACKAGE_PREFIX}-python-jsonschema"
|
|
"${MINGW_PACKAGE_PREFIX}-gettext-tools"
|
|
"intltool"
|
|
"po4a")
|
|
# Disable strip option to write backtraces with drmingw
|
|
options=('!strip')
|
|
source=("https://github.com/darktable-org/${_realname}/releases/download/release-${pkgver}/${_realname}-${pkgver}.tar.xz"{,.asc})
|
|
sha256sums=('02f1aa9ae93949e7bc54c34eeb5ff92c2b87f95d2547865df55c60467564ee11'
|
|
'SKIP')
|
|
validpgpkeys=('F10F9686652B0E949FCD94C318DCA123F949BD3B') # Pascal Obry <pascal@obry.net>
|
|
|
|
build() {
|
|
declare -a extra_config
|
|
if check_option "debug" "n"; then
|
|
extra_config+=("-DCMAKE_BUILD_TYPE=Release")
|
|
else
|
|
extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
|
|
fi
|
|
|
|
MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
|
|
cmake \
|
|
-GNinja \
|
|
-DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \
|
|
"${extra_config[@]}" \
|
|
-DBINARY_PACKAGE_BUILD=ON \
|
|
-DBUILD_MSYS2_INSTALL=ON \
|
|
-DBUILD_CURVE_TOOLS=ON \
|
|
-DBUILD_NOISE_TOOLS=ON \
|
|
-DDONT_USE_INTERNAL_LIBRAW=ON \
|
|
-S "${_realname}-${pkgver}" \
|
|
-B "build-${MSYSTEM}"
|
|
|
|
cmake --build "build-${MSYSTEM}"
|
|
}
|
|
|
|
package() {
|
|
DESTDIR="${pkgdir}" cmake --install "build-${MSYSTEM}"
|
|
|
|
install -Dm644 "${srcdir}/${_realname}-${pkgver}/LICENSE" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
|
|
}
|