107 lines
3.7 KiB
Bash
107 lines
3.7 KiB
Bash
# Contributor: Mehdi Chinoune <mehdi.chinoune@hotmail.com>
|
|
|
|
_realname=qt5-quickcontrols2
|
|
pkgbase="mingw-w64-${_realname}"
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}"
|
|
"${MINGW_PACKAGE_PREFIX}-${_realname}-debug")
|
|
_qtver=5.15.17
|
|
pkgver=${_qtver}+kde+r5
|
|
pkgrel=1
|
|
pkgdesc="Next generation user interface controls based on Qt Quick (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url='https://www.qt.io/'
|
|
msys2_references=(
|
|
"cpe: cpe:/a:qt:qt"
|
|
)
|
|
license=('spdx:LGPL-3.0-only WITH Qt-GPL-exception-1.0 AND GPL-3.0-or-later AND GPL-2.0-or-later AND GFDL-1.3-no-invariants-only')
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
|
|
"${MINGW_PACKAGE_PREFIX}-qt5-declarative"
|
|
"git"
|
|
"rsync")
|
|
_pkgfn="${_realname/5-/}"
|
|
_commit=9bdcebd1c093b6f0886e3a739711470cc37b1adb
|
|
source=(git+https://invent.kde.org/qt/qt/$_pkgfn#commit=$_commit)
|
|
sha256sums=('92635cab9c876c6bc8801d2927e1192d465a6eb2dd8ac959603d69fa1764285a')
|
|
|
|
pkgver() {
|
|
cd $_pkgfn
|
|
echo "${_qtver}+kde+r"`git rev-list --count v${_qtver}-lts-lgpl..$_commit`
|
|
}
|
|
|
|
build() {
|
|
mkdir -p build-${MSYSTEM} && cd build-${MSYSTEM}
|
|
|
|
qmake ../${_pkgfn}
|
|
|
|
MSYS2_ARG_CONV_EXCL='*' \
|
|
make
|
|
}
|
|
|
|
check() {
|
|
cd build-${MSYSTEM}
|
|
make check -j1 -k
|
|
}
|
|
|
|
package_qt5-quickcontrols2() {
|
|
depends=("${MINGW_PACKAGE_PREFIX}-qt5-declarative")
|
|
optdepends=("${MINGW_PACKAGE_PREFIX}-qt5-graphicaleffects")
|
|
groups=("${MINGW_PACKAGE_PREFIX}-qt5")
|
|
|
|
cd build-${MSYSTEM}
|
|
|
|
# Fix Makefiles
|
|
local PREFIX_WIN=$(cygpath -am ${MINGW_PREFIX})
|
|
find "${srcdir}/build-${MSYSTEM}" -type f \( -name 'Makefile*' \) \
|
|
-exec sed -i -e "s|${PREFIX_WIN:0:2}\$(INSTALL_ROOT|\$(INSTALL_ROOT|g" {} \;
|
|
find "${srcdir}/build-${MSYSTEM}" -type f \( -name 'Makefile*' \) \
|
|
-exec sed -i -e "s|)${PREFIX_WIN:2}|)${MINGW_PREFIX}|g" {} \;
|
|
|
|
local PKGDIR=$(cygpath -am "${pkgdir}")
|
|
make INSTALL_ROOT="${PKGDIR}" install
|
|
|
|
install -d "$pkgdir${MINGW_PREFIX}"/share/licenses/${_realname}
|
|
install -Dm644 $srcdir/${_pkgfn}/LICENSE* -t "$pkgdir${MINGW_PREFIX}"/share/licenses/${_realname}
|
|
|
|
# Seperate debug-info files
|
|
mv -f "${pkgdir}${MINGW_PREFIX}/lib"/*.debug "${pkgdir}${MINGW_PREFIX}/bin"/ || true
|
|
rsync -armR --remove-source-files --include="*/" --include="*.debug" --exclude="*" --prune-empty-dirs "${pkgdir}"/.${MINGW_PREFIX} "${srcdir}"/${MSYSTEM}-debug/
|
|
|
|
# Fix paths in *.pri, *prl and *.pc files:
|
|
# $(cygpath -m ${MINGW_PREFIX}) -> $(cygpath -m "${pkgdir}"${MINGW_PREFIX})
|
|
local PKGDIR_PREFIX_WIN=$(cygpath -m "${pkgdir}"${MINGW_PREFIX})
|
|
local FAKE_PREFIX_FOR_REPLACE="@@QT_REAL_PREFIX/dir@@"
|
|
|
|
find "${pkgdir}${MINGW_PREFIX}/share/qt5" -type f \( -name '*.pri' -o -name '*.prl' \) \
|
|
-exec sed -i -e "s|${PREFIX_WIN}|${FAKE_PREFIX_FOR_REPLACE}|g" {} \;
|
|
|
|
find "${pkgdir}${MINGW_PREFIX}/lib" -type f \( -name '*.pri' -o -name '*.prl' \) \
|
|
-exec sed -i -e "s|${PREFIX_WIN}|${FAKE_PREFIX_FOR_REPLACE}|g" {} \;
|
|
|
|
find "${pkgdir}${MINGW_PREFIX}/lib/pkgconfig" -type f -name '*.pc' \
|
|
-exec sed -i -e "s|${PREFIX_WIN}|${MINGW_PREFIX}|g" {} \;
|
|
|
|
find "${pkgdir}${MINGW_PREFIX}/lib/pkgconfig" -type f -name '*.pc' \
|
|
-exec sed -i -e "s|${PKGDIR_PREFIX_WIN}|${MINGW_PREFIX}|g" {} \;
|
|
}
|
|
|
|
package_qt5-quickcontrols2-debug() {
|
|
depends=("${MINGW_PACKAGE_PREFIX}-qt5-declarative-debug"
|
|
"${MINGW_PACKAGE_PREFIX}-${_realname}")
|
|
groups=("${MINGW_PACKAGE_PREFIX}-qt5-debug")
|
|
options=('!strip')
|
|
|
|
cp -rf "${srcdir}"/${MSYSTEM}-debug${MINGW_PREFIX} "${pkgdir}"/
|
|
}
|
|
|
|
# template start; name=mingw-w64-splitpkg-wrappers; version=1.0;
|
|
# vim: set ft=bash :
|
|
|
|
# generate wrappers
|
|
for _name in "${pkgname[@]}"; do
|
|
_short="package_${_name#${MINGW_PACKAGE_PREFIX}-}"
|
|
_func="$(declare -f "${_short}")"
|
|
eval "${_func/#${_short}/package_${_name}}"
|
|
done
|
|
# template end;
|