51 lines
1.4 KiB
Bash
51 lines
1.4 KiB
Bash
# Maintainer: llm96 <llm96@fervidex.net>
|
|
|
|
_realname=args
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
|
|
pkgver=6.4.7
|
|
pkgrel=1
|
|
pkgdesc="Simple header-only C++ argument parser library (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
msys2_references=(
|
|
'aur: args'
|
|
)
|
|
url="https://github.com/Taywee/args"
|
|
license=('spdx:MIT')
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-cmake"
|
|
"${MINGW_PACKAGE_PREFIX}-ninja"
|
|
"${MINGW_PACKAGE_PREFIX}-cc")
|
|
source=("$url/archive/$pkgver/${_realname}-$pkgver.tar.gz")
|
|
sha256sums=('ae53d120609ecf44ff079b6992b4b54d6c25e9d647d06f46d9f68fe1476c0454')
|
|
|
|
build() {
|
|
declare -a extra_config
|
|
if check_option "debug" "n"; then
|
|
extra_config+=("-DCMAKE_BUILD_TYPE=Release")
|
|
else
|
|
extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
|
|
fi
|
|
|
|
MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
|
|
cmake \
|
|
-GNinja \
|
|
-DCMAKE_INSTALL_PREFIX="${MINGW_PREFIX}" \
|
|
"${extra_config[@]}" \
|
|
-DARGS_BUILD_EXAMPLE=OFF \
|
|
-S "${_realname}-${pkgver}" \
|
|
-B "build-${MSYSTEM}"
|
|
|
|
cmake --build "build-${MSYSTEM}"
|
|
}
|
|
|
|
check() {
|
|
cmake --build "build-${MSYSTEM}" --target test
|
|
}
|
|
|
|
package() {
|
|
DESTDIR="${pkgdir}" cmake --install "build-${MSYSTEM}"
|
|
|
|
install -Dm644 "${srcdir}/${_realname}-${pkgver}/LICENSE" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
|
|
}
|