29a2b9d820
* python-bleach: Update to 3.1.0 * python-entrypoints: Update to 0.3 * python-more-itertools: Update to 5.0.0 * python-jupyter-notebook: Update to 5.7.4 * python-jedi: Update to 0.13.2 * python-soupsieve: Update to 1.7.0
78 lines
2.6 KiB
Bash
78 lines
2.6 KiB
Bash
# Maintainer: Andrew Sun <adsun701@gmail.com>
|
|
|
|
_realname=more-itertools
|
|
pkgbase=mingw-w64-python-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-python2-${_realname}" "${MINGW_PACKAGE_PREFIX}-python3-${_realname}")
|
|
pkgver=5.0.0
|
|
pkgrel=1
|
|
pkgdesc="More routines for operating on iterables, beyond itertools (mingw-w64)"
|
|
arch=('any')
|
|
url="https://github.com/erikrose/more-itertools"
|
|
license=('MIT')
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-python2"
|
|
"${MINGW_PACKAGE_PREFIX}-python3"
|
|
"${MINGW_PACKAGE_PREFIX}-python2-setuptools"
|
|
"${MINGW_PACKAGE_PREFIX}-python3-setuptools"
|
|
"${MINGW_PACKAGE_PREFIX}-python2-six"
|
|
"${MINGW_PACKAGE_PREFIX}-python3-six")
|
|
options=('staticlibs' 'strip' '!debug')
|
|
source=("${_realname}-${pkgver}.tar.gz"::"https://github.com/erikrose/more-itertools/archive/${pkgver}.tar.gz")
|
|
sha256sums=('a2dd59cdb7287d738b3c745558f0812b69b519cda21726b180b09d9d68d8b461')
|
|
|
|
prepare() {
|
|
cd "${srcdir}"
|
|
for pver in {2,3}; do
|
|
rm -rf python${pver}-build-${CARCH} | true
|
|
cp -r "${_realname}-${pkgver}" "python${pver}-build-${CARCH}"
|
|
done
|
|
}
|
|
|
|
build() {
|
|
cd "${srcdir}"
|
|
for pver in {2,3}; do
|
|
msg "Python ${pver} build for ${CARCH}"
|
|
cd "${srcdir}/python${pver}-build-${CARCH}"
|
|
${MINGW_PREFIX}/bin/python${pver} setup.py build
|
|
done
|
|
}
|
|
|
|
package_python3-more-itertools() {
|
|
depends=("${MINGW_PACKAGE_PREFIX}-python3"
|
|
"${MINGW_PACKAGE_PREFIX}-python3-six")
|
|
|
|
cd "${srcdir}/python3-build-${CARCH}"
|
|
MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
|
|
${MINGW_PREFIX}/bin/python3 setup.py install --prefix=${MINGW_PREFIX} \
|
|
--root="${pkgdir}" --optimize=1 --skip-build
|
|
|
|
install -Dm644 LICENSE "${pkgdir}"${MINGW_PREFIX}/share/licenses/python3-${_realname}/LICENSE
|
|
}
|
|
|
|
package_python2-more-itertools() {
|
|
depends=("${MINGW_PACKAGE_PREFIX}-python2"
|
|
"${MINGW_PACKAGE_PREFIX}-python2-six")
|
|
|
|
cd "${srcdir}/python2-build-${CARCH}"
|
|
MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
|
|
${MINGW_PREFIX}/bin/python2 setup.py install --prefix=${MINGW_PREFIX} \
|
|
--root="${pkgdir}" --optimize=1 --skip-build
|
|
|
|
install -Dm644 LICENSE "${pkgdir}"${MINGW_PREFIX}/share/licenses/python2-${_realname}/LICENSE
|
|
}
|
|
|
|
package_mingw-w64-i686-python2-more-itertools() {
|
|
package_python2-more-itertools
|
|
}
|
|
|
|
package_mingw-w64-i686-python3-more-itertools() {
|
|
package_python3-more-itertools
|
|
}
|
|
|
|
package_mingw-w64-x86_64-python2-more-itertools() {
|
|
package_python2-more-itertools
|
|
}
|
|
|
|
package_mingw-w64-x86_64-python3-more-itertools() {
|
|
package_python3-more-itertools
|
|
}
|