48 lines
1.5 KiB
Bash
48 lines
1.5 KiB
Bash
# Maintainer: Miloš Komarčević <miloskomarcevic@aim.com>
|
|
|
|
_realname=rawpy
|
|
pkgbase=mingw-w64-python-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
|
|
pkgver=0.17.0
|
|
pkgrel=1
|
|
pkgdesc='RAW image processing for Python, a wrapper for libraw (mingw-w64)'
|
|
arch=('any')
|
|
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32')
|
|
url='https://github.com/letmaik/rawpy'
|
|
license=('MIT')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-libraw"
|
|
"${MINGW_PACKAGE_PREFIX}-python-numpy")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-python-setuptools"
|
|
"${MINGW_PACKAGE_PREFIX}-cython")
|
|
options=('staticlibs' 'strip' '!debug')
|
|
source=("python-$_realname-$pkgver.tar.gz"::"${url}/archive/v${pkgver}.tar.gz")
|
|
sha256sums=('0a67c71ca9b36ca7e973b723a4498501d8e4f74b7adee2694ece7acce9b84e50')
|
|
|
|
prepare() {
|
|
cd "${srcdir}"
|
|
|
|
rm -rf python-build-${MINGW_ARCH} | true
|
|
cp -r "${_realname}-${pkgver}" "python-build-${MINGW_ARCH}"
|
|
}
|
|
|
|
build() {
|
|
msg "Python build for ${MINGW_ARCH}"
|
|
cd "${srcdir}/python-build-${MINGW_ARCH}"
|
|
${MINGW_PREFIX}/bin/python setup.py build
|
|
}
|
|
|
|
check() {
|
|
msg "Python test for ${MINGW_ARCH}"
|
|
cd "${srcdir}/python-build-${MINGW_ARCH}"
|
|
${MINGW_PREFIX}/bin/python setup.py check --strict
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/python-build-${MINGW_ARCH}"
|
|
MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
|
|
${MINGW_PREFIX}/bin/python setup.py install --prefix=${MINGW_PREFIX} \
|
|
--root="${pkgdir}" --optimize=1 --skip-build
|
|
|
|
install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
|
|
}
|