54 lines
2.1 KiB
Bash
54 lines
2.1 KiB
Bash
# Maintainer: Sarah Ottinger <schalaalexiazeal@gmail.com>
|
|
|
|
_realname=cloudpickle
|
|
pkgbase=mingw-w64-python-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
|
|
pkgver=2.2.1
|
|
pkgrel=2
|
|
pkgdesc='Extended pickling support for Python objects (mingw-w64)'
|
|
arch=('any')
|
|
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32' 'clangarm64')
|
|
msys2_references=(
|
|
'pypi: cloudpickle'
|
|
)
|
|
url="https://github.com/cloudpipe/cloudpickle"
|
|
license=('spdx:BSD-3-Clause')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-python")
|
|
checkdepends=("${MINGW_PACKAGE_PREFIX}-python-pytest"
|
|
"${MINGW_PACKAGE_PREFIX}-python-psutil"
|
|
"${MINGW_PACKAGE_PREFIX}-python-tornado"
|
|
"${MINGW_PACKAGE_PREFIX}-python-numpy")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-python-setuptools")
|
|
options=('!emptydirs')
|
|
source=("https://files.pythonhosted.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
|
|
sha256sums=('d89684b8de9e34a2a43b3460fbca07d09d6e25ce858df4d5a44240403b6178f5')
|
|
|
|
prepare() {
|
|
rm -rf python-build-${MSYSTEM} | true
|
|
cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}"
|
|
}
|
|
|
|
build() {
|
|
msg "Python build for ${MSYSTEM}"
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
${MINGW_PREFIX}/bin/python setup.py build
|
|
}
|
|
|
|
check() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}/tests/cloudpickle_testpkg"
|
|
${MINGW_PREFIX}/bin/python setup.py build || warning "Tests failed"
|
|
cd ../..
|
|
PYTHONPATH="$PWD/tests/cloudpickle_testpkg/build/lib/" \
|
|
${MINGW_PREFIX}/bin/pytest --deselect tests/cloudpickle_file_test.py::CloudPickleFileTests::test_pickling_special_file_handles \
|
|
--deselect tests/cloudpickle_test.py::CloudPickleTest::test_pickling_file_handles \
|
|
--deselect tests/cloudpickle_test.py::Protocol2CloudPickleTest::test_pickling_file_handles || warning "Tests failed"
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
|
|
${MINGW_PREFIX}/bin/python setup.py install --prefix=${MINGW_PREFIX} \
|
|
--root="${pkgdir}" --optimize=1 --skip-build
|
|
install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
|
|
}
|