8519df2bf9
Which is what they used up to now, so rebuilds don't break. We can rebuild them against cython v3 later.
69 lines
2.5 KiB
Bash
69 lines
2.5 KiB
Bash
# Contributor: Raed Rizqie <raed.rizqie@gmail.com>
|
|
|
|
_realname=pygame
|
|
pkgbase=mingw-w64-python-${_realname}
|
|
pkgname=${MINGW_PACKAGE_PREFIX}-python-${_realname}
|
|
pkgver=2.5.2
|
|
pkgrel=1
|
|
pkgdesc='A Python library for making multimedia applications like games (mingw-w64)'
|
|
arch=('any')
|
|
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32')
|
|
license=('spdx:LGPL-2.1')
|
|
url='https://www.pygame.org'
|
|
depends=("${MINGW_PACKAGE_PREFIX}-python"
|
|
"${MINGW_PACKAGE_PREFIX}-flac"
|
|
"${MINGW_PACKAGE_PREFIX}-freetype"
|
|
"${MINGW_PACKAGE_PREFIX}-libjpeg-turbo"
|
|
"${MINGW_PACKAGE_PREFIX}-libmodplug"
|
|
"${MINGW_PACKAGE_PREFIX}-libogg"
|
|
"${MINGW_PACKAGE_PREFIX}-libpng"
|
|
"${MINGW_PACKAGE_PREFIX}-libtiff"
|
|
"${MINGW_PACKAGE_PREFIX}-libvorbis"
|
|
"${MINGW_PACKAGE_PREFIX}-libwebp"
|
|
"${MINGW_PACKAGE_PREFIX}-mpg123"
|
|
"${MINGW_PACKAGE_PREFIX}-opus"
|
|
"${MINGW_PACKAGE_PREFIX}-opusfile"
|
|
"${MINGW_PACKAGE_PREFIX}-portmidi"
|
|
"${MINGW_PACKAGE_PREFIX}-SDL2"
|
|
"${MINGW_PACKAGE_PREFIX}-SDL2_image"
|
|
"${MINGW_PACKAGE_PREFIX}-SDL2_mixer"
|
|
"${MINGW_PACKAGE_PREFIX}-SDL2_ttf"
|
|
"${MINGW_PACKAGE_PREFIX}-zlib")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
|
|
"${MINGW_PACKAGE_PREFIX}-python-installer"
|
|
"${MINGW_PACKAGE_PREFIX}-python-setuptools"
|
|
"${MINGW_PACKAGE_PREFIX}-python-wheel"
|
|
"${MINGW_PACKAGE_PREFIX}-cc"
|
|
"${MINGW_PACKAGE_PREFIX}-cython0")
|
|
source=(https://github.com/pygame/pygame/archive/refs/tags/${pkgver}.tar.gz
|
|
001-setup-fixes.patch
|
|
002-camera-extension-fixes.patch)
|
|
sha256sums=('46427b2b35060303b06a06a56c07a9e8e55b26cd4c434b792ed78244d2023e05'
|
|
'bbc384971b97e86b8f5a383d48da31b787f5029da0171b7dc2f85c34f4b8d44b'
|
|
'f2815f02cdcb8dd94a9a86c2e913c9e80f5c204b69b521b885b12329666e6dcd')
|
|
|
|
prepare() {
|
|
cd "${_realname}-${pkgver}"
|
|
|
|
patch -p1 -i ${srcdir}/001-setup-fixes.patch
|
|
patch -p1 -i ${srcdir}/002-camera-extension-fixes.patch
|
|
}
|
|
|
|
build() {
|
|
cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
|
|
|
|
CFLAGS+=" -Wno-incompatible-function-pointer-types"
|
|
|
|
${MINGW_PREFIX}/bin/python -m build --wheel --skip-dependency-check --no-isolation
|
|
}
|
|
|
|
package() {
|
|
cd "python-build-${MSYSTEM}"
|
|
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
${MINGW_PREFIX}/bin/python -m installer --prefix=${MINGW_PREFIX} \
|
|
--destdir="${pkgdir}" dist/*.whl
|
|
|
|
install -Dm644 docs/LGPL.txt "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE.txt"
|
|
}
|