56 lines
1.9 KiB
Bash
56 lines
1.9 KiB
Bash
# Contributor: Liu Pak Hin <wl@m-labs.hk>
|
|
|
|
_realname=rapidfuzz
|
|
pkgbase=mingw-w64-python-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
|
|
pkgver=3.6.2
|
|
pkgrel=1
|
|
pkgdesc="Rapid fuzzy string matching. (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
msys2_references=(
|
|
'pypi: rapidfuzz'
|
|
)
|
|
license=('spdx:MIT')
|
|
url="https://maxbachmann.github.io/RapidFuzz/"
|
|
msys2_repository_url="https://github.com/maxbachmann/RapidFuzz/"
|
|
depends=(
|
|
"${MINGW_PACKAGE_PREFIX}-python"
|
|
)
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
|
|
"${MINGW_PACKAGE_PREFIX}-python-installer"
|
|
"${MINGW_PACKAGE_PREFIX}-python-setuptools"
|
|
"${MINGW_PACKAGE_PREFIX}-python-scikit-build"
|
|
"${MINGW_PACKAGE_PREFIX}-rapidfuzz-cpp"
|
|
"${MINGW_PACKAGE_PREFIX}-cython"
|
|
"${MINGW_PACKAGE_PREFIX}-cc")
|
|
checkdepends=("${MINGW_PACKAGE_PREFIX}-python-pytest-cov"
|
|
"${MINGW_PACKAGE_PREFIX}-python-pytest-runner")
|
|
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
|
|
sha256sums=('cf911e792ab0c431694c9bf2648afabfd92099103f2e31492893e078ddca5e1a')
|
|
|
|
prepare(){
|
|
cd "${srcdir}"
|
|
cp -r "RapidFuzz-${pkgver}" "python-build-${MSYSTEM}"
|
|
rm -rf "python-build-${MSYSTEM}/extern"
|
|
cp -r "${_realname}-${pkgver}/extern" "python-build-${MSYSTEM}/extern"
|
|
}
|
|
|
|
build() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
${MINGW_PREFIX}/bin/python -m build --wheel --skip-dependency-check --no-isolation
|
|
}
|
|
|
|
check() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
${MINGW_PREFIX}/bin/python -m pytest || warning "Tests failed"
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
${MINGW_PREFIX}/bin/python -m installer --prefix=${MINGW_PREFIX} \
|
|
--destdir="${pkgdir}" dist/*.whl
|
|
install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
|
|
}
|