71 lines
1.6 KiB
Bash
71 lines
1.6 KiB
Bash
# Maintainer: Rafal Brzegowy <rafal.brzegowy@yahoo.com>
|
|
|
|
_realname=lis
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
|
|
pkgver=2.0.33
|
|
pkgrel=3
|
|
pkgdesc='Library of Iterative Solvers for linear systems (mingw-w64)'
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-msmpi")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-msmpi" "${MINGW_PACKAGE_PREFIX}-autotools")
|
|
options=('!docs')
|
|
license=('BSD')
|
|
url='https://www.ssisc.org/lis/'
|
|
source=(https://www.ssisc.org/lis/dl/${_realname}-${pkgver}.zip)
|
|
sha256sums=('9C3A9294D640652DBE278BBAC673FF7855A3785253B81CC2724D06B58A0B2285')
|
|
|
|
prepare() {
|
|
cd "${srcdir}/${_realname}-${pkgver}"
|
|
autoreconf -fiv
|
|
}
|
|
|
|
build() {
|
|
cd "${srcdir}"
|
|
[[ -d "build-${MSYSTEM}" ]] && rm -rf "build-${MSYSTEM}"
|
|
cp -r "${_realname}-${pkgver}" "build-${MSYSTEM}"
|
|
|
|
cd "build-${MSYSTEM}"
|
|
declare -a extra_conf
|
|
case ${MSYSTEM} in
|
|
CLANG*)
|
|
extra_conf+=("--disable-f90 --disable-fortran");;
|
|
*)
|
|
extra_conf+=("--enable-f90 --enable-fortran");;
|
|
esac
|
|
|
|
./configure \
|
|
--prefix=${MINGW_PREFIX} \
|
|
--build=${MINGW_CHOST} \
|
|
--host=${MINGW_CHOST} \
|
|
--enable-mpi \
|
|
--enable-omp \
|
|
--enable-shared \
|
|
--enable-fma \
|
|
--enable-sse2 \
|
|
--enable-longlong \
|
|
--enable-longdouble \
|
|
--enable-quad \
|
|
--enable-complex \
|
|
--disable-test \
|
|
--with-gnu-ld \
|
|
${extra_conf}
|
|
|
|
make
|
|
}
|
|
|
|
check() {
|
|
cd "${srcdir}/build-${MSYSTEM}"
|
|
make check || true
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/build-${MSYSTEM}"
|
|
make install DESTDIR="${pkgdir}"
|
|
|
|
install -Dm644 COPYING ${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE
|
|
}
|
|
|
|
# vim: ts=2 sw=2 et:
|