45 lines
1.7 KiB
Bash
45 lines
1.7 KiB
Bash
# Maintainer: fauxpark <fauxpark@gmail.com>
|
|
|
|
_realname=argcomplete
|
|
pkgbase=mingw-w64-python-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
|
|
pkgver=3.4.0
|
|
pkgrel=1
|
|
pkgdesc="Easy, extensible command line tab completion of arguments for your Python script (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32' 'clangarm64')
|
|
msys2_references=(
|
|
'pypi: argcomplete'
|
|
)
|
|
msys2_repository_url='https://github.com/kislyuk/argcomplete'
|
|
url='https://kislyuk.github.io/argcomplete/'
|
|
license=('spdx:Apache-2.0')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-python")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
|
|
"${MINGW_PACKAGE_PREFIX}-python-installer"
|
|
"${MINGW_PACKAGE_PREFIX}-python-setuptools"
|
|
"${MINGW_PACKAGE_PREFIX}-python-setuptools-scm"
|
|
"${MINGW_PACKAGE_PREFIX}-python-wheel")
|
|
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
|
|
sha256sums=('c2abcdfe1be8ace47ba777d4fce319eb13bf8ad9dace8d085dcad6eded88057f')
|
|
|
|
build() {
|
|
cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
|
|
${MINGW_PREFIX}/bin/python -m build --wheel --skip-dependency-check --no-isolation
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
${MINGW_PREFIX}/bin/python -m installer --prefix=${MINGW_PREFIX} \
|
|
--destdir="${pkgdir}" dist/*.whl
|
|
|
|
# Undo path translation
|
|
for _f in "${pkgdir}${MINGW_PREFIX}"/bin/*; do
|
|
sed -e '1 { s/^#!.*python.*$/#!\/usr\/bin\/env python/ }' -i ${_f}
|
|
done
|
|
|
|
install -Dm644 LICENSE.rst "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE.rst"
|
|
}
|