# Maintainer: Alexey Pavlov <alexpux@gmail.com>

pkgname=('catgets' 'libcatgets' 'libcatgets-devel')
pkgver=1.1
pkgrel=2
pkgdesc="catgets message catalog API"
groups=('base')
arch=('i686' 'x86_64')
license=('custom')
url="http://www.gnu.org/software/libc/"
makedepends=('libiconv-devel' 'gettext-devel')
source=(catgets-${pkgver}.tar.bz2
        catgets-1.1-2.src.patch
        catgets-1.1-msys2.patch)
sha1sums=('332abe2fbd4e26dfc4cb652cd64de90b46f656c4'
          '2d3814700918ca9900b1cf783befff13fac992e6'
          '686fe1c410174fcc9f16bcef5c370c05888885df')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"

  patch -p2 -i $srcdir/catgets-1.1-2.src.patch
  patch -p1 -i $srcdir/catgets-1.1-msys2.patch
}

build() {
  cd "$srcdir/$pkgname-$pkgver"

  make CC=gcc CCLD=gcc AR=ar OSTYPE=msys
  make DESTDIR=${srcdir}/dest install
}

package_catgets() {
  depends=('libiconv' 'libintl' 'libcatgets')

  mkdir -p ${pkgdir}/usr/bin
  cp -f ${srcdir}/dest/usr/bin/gencat.exe ${pkgdir}/usr/bin/
}

package_libcatgets() {
  pkgesc="message catalog API library"
  groups=('libraries')
  depends=('gcc-libs')

  mkdir -p ${pkgdir}/usr/bin
  cp -f ${srcdir}/dest/usr/bin/*.dll ${pkgdir}/usr/bin/
}

package_libcatgets-devel() {
  pkgdesc="Libcatgets headers and libraries"
  groups=('development')
  depends=("libcatgets=${pkgver}")
  options=('staticlibs')

  mkdir -p ${pkgdir}/usr/{include,lib}
  cp -rf ${srcdir}/dest/usr/include ${pkgdir}/usr/
  cp -rf ${srcdir}/dest/usr/lib ${pkgdir}/usr/
}
