# Maintainer: Alexey Pavlov <alexpux@gmail.com>

pkgname=coreutils
pkgver=8.23
pkgrel=4
pkgdesc="The basic file, shell and text manipulation utilities of the GNU operating system"
arch=('i686' 'x86_64')
license=('GPL3')
url="http://www.gnu.org/software/coreutils"
groups=('base')
depends=('gmp' 'libiconv' 'libintl')
makedepends=('gmp-devel' 'libiconv-devel' 'gettext-devel' 'help2man')
install=${pkgname}.install
source=(ftp://ftp.gnu.org/gnu/$pkgname/$pkgname-$pkgver.tar.xz{,.sig}
        001-coreutils-8.23-2.src.patch
        002-fix-dummy-man-invocation.patch
        005-manifest.patch
        006-msys1-0x0d.patch
        008-msys2-src.patch
        009-msysize.patch)
md5sums=('abed135279f87ad6762ce57ff6d89c41'
         'SKIP'
         '6a5a1cb7de1fdea8373484371a3fb4cd'
         'e6abf5162a6cfa5662c2a7f0e55cd4b1'
         '78fdb4dd2df493df4ae24448e964d076'
         '61aa69467df9084fe4611b737723f97b'
         '81daac14dff78aadd8e935d8213727ad'
         'a159a8ab3cd0a5129f420db8e1102770')

prepare() {
  cd ${srcdir}/${pkgname}-${pkgver}

  patch -p2 -i $srcdir/001-coreutils-8.23-2.src.patch
  patch -p1 -i $srcdir/002-fix-dummy-man-invocation.patch
  patch -p1 -i $srcdir/005-manifest.patch
  patch -p1 -i $srcdir/006-msys1-0x0d.patch
  patch -p1 -i $srcdir/008-msys2-src.patch
  patch -p1 -i $srcdir/009-msysize.patch

  autoreconf -fi
}

build() {
  [[ -d $srcdir/build-${CHOST} ]] && rm -rf $srcdir/build-${CHOST}
  mkdir -p $srcdir/build-${CHOST} && cd $srcdir/build-${CHOST}

  #cd ${srcdir}/${pkgname}-${pkgver}
  ../${pkgname}-${pkgver}/configure \
    --build=${CHOST} \
    --prefix=/usr \
    --libexecdir=/usr/lib \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --program-transform-name=s/kill/gkill/ \
    --without-libintl-prefix \
    --without-libiconv-prefix \
    --enable-install-program=arch,hostname \
    --enable-no-install-program=uptime

  make
}

package() {
  cd $srcdir/build-${CHOST}
  make DESTDIR=${pkgdir} install

  #mkdir -p ${pkgdir}/usr/etc
  install -Dm644 ${srcdir}/${pkgname}-${pkgver}/src/dircolors.hin ${pkgdir}/etc/DIR_COLORS
}
