# Maintainer: Alexey Pavlov <alexpux@gmail.com>

pkgname=('libffi' 'libffi-devel')
pkgver=3.2.1
pkgrel=1
pkgdesc="Portable, high level programming interface to various calling conventions"
arch=('i686' 'x86_64')
url="http://sourceware.org/libffi/"
groups=('libraries')
license=('MIT')
depends=()
checkdepends=('dejagnu')
install=libffi.install
source=(ftp://sourceware.org/pub/libffi/libffi-${pkgver}.tar.gz
        libffi-3.2.1-msysize.patch)
sha1sums=('280c265b789e041c02e5c97815793dfc283fb1e6'
          'e43e2ee32b6c357f7e267f19f8e529378bca85ac')

prepare() {
  cd $pkgname-$pkgver
  patch -p1 -i $srcdir/libffi-3.2.1-msysize.patch

  autoreconf -fi
}

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --build=${CHOST} \
    --enable-static \
    --enable-shared
  make
  make DESTDIR="$srcdir/dest" install
}

check() {
  cd $pkgname-$pkgver
  make check
}

package_libffi() {
  mkdir -p $pkgdir/usr/bin
  cp -f $srcdir/dest/usr/bin/*.dll $pkgdir/usr/bin/
  cp -rf $srcdir/dest/usr/share $pkgdir/usr/
  install -Dm644 $srcdir/$pkgname-$pkgver/LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}

package_libffi-devel() {
  pkgdesc="Libffi headers and libraries"
  groups=('development')
  options=('staticlibs')
  depends=("libffi=${pkgver}")

  mkdir -p $pkgdir/usr
  #cp -rf $srcdir/dest/usr/include $pkgdir/usr/
  cp -rf $srcdir/dest/usr/lib $pkgdir/usr/
}
