# Maintainer: Alexey Pavlov <alexpux@gmail.com>

pkgname=('liblzo2' 'liblzo2-devel')
pkgver=2.09
pkgrel=1
pkgdesc="Portable lossless data compression library"
arch=('i686' 'x86_64')
url="http://www.oberhumer.com/opensource/lzo"
license=('GPL')
makedepends=('gcc' 'make' 'patch')
groups=('libraries' 'compression')
source=(http://www.oberhumer.com/opensource/lzo/download/lzo-${pkgver}.tar.gz
        lzo-2.07-msys2.patch)
options=(!libtool)
md5sums=('c7ffc9a103afe2d1bba0b015e7aa887f'
         'ae2b844f8a17d320aaa3511e8d355562')

prepare() {
  cd "${srcdir}/lzo-${pkgver}"
  patch -p1 -i ${srcdir}/lzo-2.07-msys2.patch
  
  autoreconf -fi
}

build() {
  cd "${srcdir}/lzo-${pkgver}"
  
  ./configure --prefix=/usr --enable-shared
  
  make
  make DESTDIR=${srcdir}/dest install
}

check() {
  cd "${srcdir}/lzo-${pkgver}"
  make test # Larger test
  make check
}

package_liblzo2() {
  depends=('gcc-libs')

  mkdir -p ${pkgdir}/usr
  cp -rf ${srcdir}/dest/usr/bin ${pkgdir}/usr/
  cp -rf ${srcdir}/dest/usr/share ${pkgdir}/usr/
}

package_liblzo2-devel() {
  pkgdesc="Liblzo2 headers and libraries"
  options=('staticlibs')
  groups=('development')
  depends=("liblzo2=${pkgver}")
  
  mkdir -p ${pkgdir}/usr
  
  cp -rf ${srcdir}/dest/usr/include ${pkgdir}/usr/
  cp -rf ${srcdir}/dest/usr/lib ${pkgdir}/usr/
}
