# Maintainer: Alexey Pavlov <Alexpux@gmail.com>

pkgbase=neon
pkgname=("lib${pkgbase}" "lib${pkgbase}-devel")
pkgver=0.30.0
pkgrel=1
pkgdesc="HTTP and WebDAV client library with a C interface"
arch=('i686' 'x86_64')
url="http://www.webdav.org/neon/"
license=('GPL' 'LGPL')
depends=('libexpat' 'openssl' 'ca-certificates')
makedepends=('libexpat-devel' 'openssl-devel')
options=('libtool') # FS#16067
source=(http://www.webdav.org/${pkgbase}/${pkgbase}-${pkgver}.tar.gz{,.asc}
        neon-0.30.0-msys2.patch)
sha1sums=('9e6297945226f90d66258b7ee05f757ff5cea10a'
          'SKIP'
          'd51ec0f89520949b3d759c88d300b9f5afc28afa')

prepare() {
  cd "${srcdir}"/${pkgbase}-${pkgver}

  patch -p1 -i ${srcdir}/neon-0.30.0-msys2.patch

  #autoreconf -fi
}

build() {
  cd "${srcdir}"/${pkgbase}-${pkgver}
  ./configure --build=${CHOST} \
    --prefix=/usr \
    --with-expat \
    --enable-shared \
    --disable-static \
    --with-ssl=openssl \
    --with-ca-bundle=/usr/ssl/certs/ca-bundle.crt
  make

  make DESTDIR="${srcdir}/dest" install
}

package_libneon() {
  groups=('libraries')

  mkdir -p ${pkgdir}/usr/bin
  cp -f ${srcdir}/dest/usr/bin/*.dll ${pkgdir}/usr/bin/
  cp -rf ${srcdir}/dest/usr/share ${pkgdir}/usr/
}

package_libneon-devel() {
  pkgdesc="Libneon headers and libraries"
  groups=('development')
  options=('staticlibs')
  depends=("libneon=${pkgver}" 'libexpat-devel' 'openssl-devel')

  mkdir -p ${pkgdir}/usr/bin
  cp -f ${srcdir}/dest/usr/bin/*-config ${pkgdir}/usr/bin/
  cp -rf ${srcdir}/dest/usr/include ${pkgdir}/usr/
  cp -rf ${srcdir}/dest/usr/lib ${pkgdir}/usr/
}
