# Maintainer: Alexey Pavlov <alexpux@gmail.com>

_realname=HTTP-Message
pkgname=perl-${_realname}
pkgver=6.06
pkgrel=2
pkgdesc="HTTP style messages"
arch=(any)
url=http://search.cpan.org/dist/HTTP-Message
groups=('perl-modules')
license=('PerlArtistic' 'GPL')
options=('!emptydirs')
depends=('perl>=5.8.8' 'perl-Encode-Locale>=1' 'perl-HTML-Parser>=3.33'
        'perl-HTTP-Date>=6' 'perl-LWP-MediaTypes>=6' 'perl-URI>=1.10')
checkdepends=('perl-IO-HTML')
conflicts=('perl-libwww<6')
source=("http://search.cpan.org/CPAN/authors/id/G/GA/GAAS/${_realname}-${pkgver}.tar.gz")
md5sums=('e563ac516e28d33f65bc0f295f625f85')

build() {
  ( export PERL_MM_USE_DEFAULT=1 PERL5LIB=""                 \
      PERL_AUTOINSTALL=--skipdeps                            \
      PERL_MM_OPT="INSTALLDIRS=vendor"     \
      PERL_MB_OPT="--installdirs vendor" \
      MODULEBUILDRC=/dev/null

    cd ${_realname}-${pkgver}
    /usr/bin/perl Makefile.PL
    make
  )
}

check() {
  ( export PERL_MM_USE_DEFAULT=1 PERL5LIB=""
    cd ${_realname}-${pkgver}
    make test
  )
}

package() {
    cd ${_realname}-${pkgver}
    make DESTDIR="$pkgdir" install
}
