# Maintainer: Allan McRae <allan@archlinux.org>

pkgname=dejagnu
pkgver=1.6.3
pkgrel=1
pkgdesc="Framework for testing other programs"
arch=('any')
url="https://www.gnu.org/software/dejagnu/"
license=('GPL')
depends=('expect')
makedepends=('autotools')
#install=dejagnu.install
source=(https://ftp.gnu.org/gnu/dejagnu/${pkgname}-${pkgver}.tar.gz{,.sig})
sha256sums=('87daefacd7958b4a69f88c6856dbd1634261963c414079d0c371f589cd66a2e3'
            'SKIP')
validpgpkeys=('D231B45ECB0B7BD8F6E7A682CE9D6843AABACC90')   # Jacob Bachmeyer

prepare() {
  cd ${srcdir}/${pkgname}-${pkgver}
  autoreconf -fiv
}

build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  ./configure --prefix=/usr
  make
}

check() {
  cd ${srcdir}/${pkgname}-${pkgver}
  make check
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  make DESTDIR=${pkgdir} install
}
