# Maintainer: Christoph Reiter <reiter.christoph@gmail.com>

_pyname=hatch-vcs
pkgname=python-hatch-vcs
pkgver=0.5.0
pkgrel=1
pkgdesc="Hatch plugin for versioning with your preferred VCS"
url="https://github.com/ofek/hatch-vcs"
msys2_references=(
  "purl: pkg:pypi/hatch-vcs"
)
license=('spdx:MIT')
arch=('any')
depends=(
  'python-hatchling'
  'python-setuptools-scm'
)
makedepends=(
  'python-build'
  'python-installer'
)
source=("https://pypi.org/packages/source/${_pyname::1}/${_pyname}/${_pyname/-/_}-${pkgver}.tar.gz")
sha256sums=('0395fa126940340215090c344a2bf4e2a77bcbe7daab16f41b37b98c95809ff9')

build() {
  cd "${_pyname/-/_}-${pkgver}"

  python -m build --wheel --no-isolation
}

package() {
  cd "${_pyname/-/_}-${pkgver}"

  python -m installer --destdir="$pkgdir" dist/*.whl
  install -Dm644 LICENSE.txt -t "$pkgdir/usr/share/licenses/$pkgname/"
}

