# Maintainer: Jeremy Drake <github@jdrake.com>

pkgname=python-zstandard
pkgver=0.24.0
pkgrel=1
pkgdesc='Python bindings to the Zstandard (zstd) compression library'
arch=('i686' 'x86_64')
url="https://github.com/indygreg/python-zstandard"
msys2_references=(
  "anitya: 147738"
  "purl: pkg:pypi/zstandard"
)
license=('spdx:BSD-3-Clause')
depends=("python")
makedepends=(
  "python-devel"
  'gcc'
  "python-setuptools"
  "python-build"
  "python-installer"
)
options=('!emptydirs')
source=("https://github.com/indygreg/${pkgname}/archive/${pkgver}.tar.gz")
sha256sums=('cc63af195abef8c57e8eba154e2d3c642d41da50063c3e83080b64798b7f25f5')

prepare() {
  cd "${pkgname}-${pkgver}"
}

build() {
  cd "${pkgname}-${pkgver}"

  python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  cd "${pkgname}-${pkgver}"

  python -m installer --destdir="${pkgdir}" dist/*.whl
  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
