# Maintainer: Alexandre Ferreira < alex.jorge.m [at] gmail.com >

_realname=cython
pkgbase=${_realname}
pkgname=('cython')
pkgver=3.1.4
pkgrel=1
pkgdesc='C-Extensions for Python'
arch=('i686' 'x86_64')
url='https://cython.org/'
msys2_repository_url="https://github.com/cython/cython"
msys2_references=(
  "purl: pkg:pypi/cython"
)
license=('spdx:Apache-2.0')
depends=('python')
conflicts=('cython0')
makedepends=(
  'gcc'
  'python-devel'
  "python-setuptools"
  "python-build"
  "python-installer"
)
source=("${_realname}-${pkgver}.tar.gz"::"https://github.com/cython/cython/archive/${pkgver}.tar.gz")
sha256sums=('0e522e0e535ae45c89fa6848d4fea1e43dd318fc865b7ae2b83972ac663269c1')

prepare() {
  cd "${_realname}-${pkgver}"
}

build() {
  cd "${_realname}-${pkgver}"

  # XXX: this changes the build path, and thus the DLL base address
  MSYSTEM=CYGWIN
  python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  cd "${_realname}-${pkgver}"

  python -m installer --destdir="${pkgdir}" dist/*.whl
}
