# Maintainer: Christoph Reiter <reiter.christoph@gmail.com>

_name=pathspec
pkgname=python-pathspec
pkgver=0.12.1
pkgrel=3
pkgdesc='Utility library for gitignore style pattern matching of file paths'
arch=('any')
url=https://github.com/cpburnz/python-pathspec
msys2_references=(
  "purl: pkg:pypi/pathspec"
)
license=('spdx: MPL-2.0')
depends=('python')
makedepends=(
  'python-build'
  'python-flit-core'
  'python-installer'
)
source=("https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz")
sha256sums=('a482d51503a1ab33b1c67a6c3813a26953dbdc71c31dacaef9a838c4e29f5712')

build() {
  cd "$_name-$pkgver"
  python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  cd "$_name-$pkgver"
  python -m installer --destdir="$pkgdir" dist/*.whl
  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}
