_realname=poetry-core
pkgname="python-${_realname}"
pkgver=2.2.1
pkgrel=1
pkgdesc='Poetry PEP 517 Build Backend'
arch=(any)
url='https://github.com/python-poetry/poetry-core'
msys2_references=(
  "purl: pkg:pypi/poetry-core"
)
license=('spdx:MIT')
depends=("python")
makedepends=(
  "python-build"
  "python-installer"
)
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname/-/_}-${pkgver}.tar.gz")
sha256sums=('97e50d8593c8729d3f49364b428583e044087ee3def1e010c6496db76bd65ac5')

build() {
  cd "${_realname/-/_}-${pkgver}"

  # https://github.com/python-poetry/poetry/issues/5547
  export GIT_DIR="$(pwd)"
  python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  cd "${_realname/-/_}-${pkgver}"

  python -m installer --destdir="${pkgdir}" dist/*.whl

  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
