# Maintainer: Johannes Schindelin <johannes.schindelin@gmx.de>

pkgname=docbook-xsl-ns
pkgver=1.79.2
pkgrel=2
pkgdesc='XML stylesheets with namespaces for Docbook-xml transformations'
arch=('any')
license=('custom')
url='https://github.com/docbook/xslt10-stylesheets'
depends=('libxml2' 'libxslt')
install="$pkgname.install"
source=(${pkgname}-${pkgver}.tar.gz::${url}/releases/download/release/${pkgver}/${pkgname%-ns}-${pkgver}.tar.gz)
sha256sums=('966188d7c05fc76eaca115a55893e643dd01a3486f6368733c9ad974fcee7a26')

package() {
  cd ${srcdir}/${pkgname%-ns}-${pkgver}

  _pkgroot=${pkgdir}/usr/share/xml/docbook-xsl-ns/${pkgver}

  install -dm755 ${_pkgroot}
  cp -R * ${_pkgroot}/

  rm ${_pkgroot}/{install.sh,build.xml} || true # ignore missing files

  install -dm755 ${pkgdir}/etc/xml
  install -Dm644 COPYING ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
}
