# Maintainer: Alexey Pavlov <alexpux@gmail.com>

_realname=Pod-Parser
pkgname=perl-${_realname}
pkgver=1.67
pkgrel=1
pkgdesc="Modules for parsing/translating POD format documents"
arch=('any')
license=('spdx:Artistic-1.0-Perl' 'spdx:GPL-1.0-or-later')
url="https://metacpan.org/dist/Pod-Parser"
msys2_references=(
  'purl: pkg:cpan/MAREKR/Pod-Parser'
)
depends=('perl')
groups=('perl-modules')
options=('!emptydirs')
source=("https://cpan.metacpan.org/authors/id/M/MA/MAREKR/${_realname}-${pkgver}.tar.gz")
sha256sums=('5deccbf55d750ce65588cd211c1a03fa1ef3aaa15d1ac2b8d85383a42c1427ea')

build() {
  cd ${_realname}-${pkgver}
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

check() {
  cd ${_realname}-${pkgver}
  make test
}

package() {
  cd ${_realname}-${pkgver}
  make DESTDIR="${pkgdir}" install
}
