# Maintainer: Alexey Pavlov <alexpux@gmail.com>

pkgbase=aspell-en
pkgname=aspell6-en
pkgver=2020.12.07
_pkg_subver=0
pkgrel=1
pkgdesc="English dictionary for aspell"
arch=('i686' 'x86_64')
url="http://aspell.net/"
license=('custom')
groups=()
makedepends=('aspell-devel')
depends=('aspell>=0.60')
provides=('aspell-en')
options=()
source=("https://ftp.gnu.org/gnu/aspell/dict/en/${pkgname}-${pkgver}-${_pkg_subver}.tar.bz2"{,.sig})
sha256sums=('4c8f734a28a088b88bb6481fcf972d0b2c3dc8da944f7673283ce487eac49fb3'
            'SKIP')
validpgpkeys=('78DEC3DB0AEA763951322BBF71C636695B147849') # Aspell Dictionary Upload <dict-upload@aspell.net>

build() {
  cd "${srcdir}/${pkgname}-${pkgver}-${_pkg_subver}"
  ./configure
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}-${_pkg_subver}"
  make DESTDIR="${pkgdir}/" install

  install -Dm644 Copyright ${pkgdir}/usr/share/licenses/aspell-en/Copyright
}
