_realname=ssh-pageant
_ver_base=1.4

pkgname="${_realname}-git"
pkgver=1.4.12.g6f47092
pkgrel=1
pkgdesc="An SSH authentication agent for Cygwin/MSYS to PuTTY's Pageant"

url="https://github.com/cuviper/ssh-pageant"
license=("GPL3")

arch=("i686" "x86_64")
makedepends=("git" "gcc")

provides=("${_realname}")
conflicts=("${_realname}")

options=("strip")

source=("${_realname}"::"git+https://github.com/cuviper/ssh-pageant.git")
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/$_realname"
  git describe --tags | sed -e "s/v//" -e "s/-/./g"
}

build() {
  cd "$srcdir/$_realname"
  make
}

package() {
  cd "$srcdir/$_realname"
  make PREFIX=${pkgdir}/usr install
}
