# Maintainer: Biswapriyo Nath <nathbappai@gmail.com>

pkgname=ncdu
pkgver=1.16
pkgrel=1
pkgdesc="Disk usage analyzer with an ncurses interface."
arch=('i686' 'x86_64')
url="https://dev.yorhel.nl/ncdu"
license=('custom:MIT')
depends=('ncurses')
makedepends=('ncurses-devel')
source=("https://dev.yorhel.nl/download/${pkgname}-${pkgver}.tar.gz"{,.asc})
sha256sums=('2b915752a183fae014b5e5b1f0a135b4b408de7488c716e325217c2513980fd4'
            'SKIP')
validpgpkeys=('74460D32B80810EBA9AFA2E962394C698C2739FA') # Yoran Heling <info@yorhel.nl>

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
