whois: New Package

whois/PKGBUILD

@@ -0,0 +1,39 @@
+# Maintainer: Felix Huettner <huettner94@gmx.de>
+
+pkgname=whois
+pkgver=5.2.7
+pkgrel=1
+pkgdesc="The whois client by Marco d'Itri"
+arch=('i686' 'x86_64')
+url="http://www.linux.it/~md/software/"
+license=('GPL')
+depends=('libcrypt' 'libidn' 'libiconv')
+makedepends=('perl' 'libcrypt-devel' 'libidn-devel' 'libiconv-devel')
+backup=('etc/whois.conf')
+source=("http://ftp.debian.org/debian/pool/main/w/whois/${pkgname}_${pkgver}.tar.xz"
+	"whois-libiconv.patch")
+md5sums=('5dc3d9d77224109f61b5dd1e7cfafebc'
+	 '83c9949c4cb0d2f4837dc500e0d4a84d')
+
+prepare() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+
+  patch -i ${srcdir}/whois-libiconv.patch
+}
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+
+  make prefix=/usr \
+       CFLAGS="$CFLAGS $CPPFLAGS" \
+       CONFIG_FILE=/etc/whois.conf \
+       HAVE_LIBIDN=1 \
+       HAVE_ICONV=1
+}
+
+package() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+
+  make prefix=/usr BASEDIR="${pkgdir}" install-whois
+  install -D -m644 whois.conf "${pkgdir}/etc/whois.conf"
+}

whois/whois-libiconv.patch

@@ -0,0 +1,10 @@
+--- Makefile	2015-01-09 03:49:00.000000000 +0100
++++ Makefile	2015-03-31 20:02:47.435187900 +0200
+@@ -39,6 +39,7 @@
+ 
+ ifdef HAVE_ICONV
+ whois_OBJECTS += simple_recode.o
++whois_LDADD += -liconv
+ DEFS += -DHAVE_ICONV
+ endif
+