Add breezy (bzr Python 3 fork)

See #1847

python-dulwich/PKGBUILD

@@ -0,0 +1,36 @@
+# Maintainer: Christoph Reiter <reiter.christoph@gmail.com>
+
+_realname=dulwich
+pkgname="python-${_realname}"
+pkgver=0.19.15
+pkgrel=1
+pkgdesc='Pure-Python implementation of the Git file formats and protocols'
+arch=('i686' 'x86_64')
+url='https://www.dulwich.io'
+license=('GPL')
+depends=('python')
+makedepends=('python3-setuptools' 'libcrypt-devel')
+source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
+sha256sums=('805a9b1932dc28b91f359f529c2e46b7623aec3ab719c96d3f2fc63d0d8d8411')
+
+prepare(){
+  cd "${srcdir}/${_realname}-${pkgver}"
+}
+
+build() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+
+  python setup.py build
+}
+
+package() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+
+  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+
+  # We are missing runtime deps, so don't bother installing the cli tools.
+  # dulwich alone is enough to get breezy working.
+  rm -Rf "${pkgdir}"/usr/bin
+
+  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}