# Maintainer: Alexey Pavlov <alexpux@gmail.com>

_realname=markupsafe
pkgbase="python-${_realname}"
pkgname=("python-${_realname}")
pkgver=2.1.5
pkgrel=4
pkgdesc="Implements a XML/HTML/XHTML Markup safe string for Python"
arch=('i686' 'x86_64')
license=('spdx:BSD-3-Clause')
url="https://pypi.python.org/pypi/MarkupSafe"
msys2_references=(
  "pypi:MarkupSafe"
)
depends=("python")
makedepends=(
  "gcc"
  "python-setuptools"
  "python-build"
  "python-installer"
)
provides=("python3-${_realname}")
conflicts=("python3-${_realname}")
replaces=("python3-${_realname}")
source=("https://pypi.python.org/packages/source/M/MarkupSafe/MarkupSafe-${pkgver}.tar.gz")
sha256sums=('d283d37a890ba4c1ae73ffadf8046435c76e7bc2247bbb63c00bd1a709c6544b')

build() {
  cd "${srcdir}/MarkupSafe-${pkgver}"
  python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  cd "${srcdir}/MarkupSafe-${pkgver}"
  python -m installer --destdir="${pkgdir}" dist/*.whl
  install -Dm644 LICENSE.rst "${pkgdir}/usr/share/licenses/python-${_realname}/LICENSE"
}