New package: amqp-cpp (#6432)

* Add amqp-cpp

* Replace tab with spaces

* Add info about maintainer

* Add (mingw-w64) to the end of description

* Download into named archive

* Install license with the package

Co-authored-by: Aleksandr Serbin <aleksandr.serbin@ee.abb.com>

mingw-w64-amqp-cpp/PKGBUILD

@@ -0,0 +1,38 @@
+# Maintainer: Aleksandr Serbin <aleksandr.serbin@gmail.com>
+
+_realname=amqp-cpp
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+pkgver=4.1.6
+pkgrel=1
+pkgdesc="C++ library for asynchronous non-blocking communication with RabbitMQ (mingw-w64)"
+arch=('any')
+url="https://github.com/CopernicaMarketingSoftware/AMQP-CPP"
+license=('Apache2.0')
+depends=()
+makedepends=("${MINGW_PACKAGE_PREFIX}-cmake")
+source=("${_realname}-${pkgver}.tar.gz"::https://github.com/CopernicaMarketingSoftware/AMQP-CPP/archive/v${pkgver}.tar.gz)
+sha256sums=('48832068dc1e25a5313dd9e96fb33ba954c19f9dc04eeca8f7b2c6cecde3afc9')
+
+build() {
+  rm -rf "${srcdir}/build-${MINGW_CHOST}"
+  mkdir "${srcdir}/build-${MINGW_CHOST}"
+  cd "${srcdir}/build-${MINGW_CHOST}"
+
+  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
+  ${MINGW_PREFIX}/bin/cmake.exe \
+    -G"MSYS Makefiles" \
+    -DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \
+    -DAMQP-CPP_BUILD_SHARED=OFF \
+    -DAMQP-CPP_LINUX_TCP=OFF \
+    "../${_realname}-${pkgver}"
+  
+  make
+}
+
+package(){
+  cd "${srcdir}/build-${MINGW_CHOST}"
+  make DESTDIR=${pkgdir} install
+  
+  install -Dm644 "${srcdir}/${_realname}-${pkgver}/LICENSE" \
+    "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
+}