[new package] python-readme-renderer 44.0

mingw-w64-python-readme-renderer/PKGBUILD

@@ -0,0 +1,38 @@
+# Maintainer: Konstantin Podsvirov <konstantin@podsvirov.pro>
+
+_pyname=readme_renderer
+_realname=${_pyname/_/-}
+pkgbase=mingw-w64-python-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
+pkgver=44.0
+pkgrel=1
+pkgdesc='Safely render long_description/README files in Warehouse (mingw-w64)'
+arch=('any')
+mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
+url='https://github.com/pypa/readme_renderer'
+license=('Apache')
+depends=("${MINGW_PACKAGE_PREFIX}-python-nh3"
+         "${MINGW_PACKAGE_PREFIX}-python-docutils"
+         "${MINGW_PACKAGE_PREFIX}-python-pygments")
+makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
+             "${MINGW_PACKAGE_PREFIX}-python-installer"
+             "${MINGW_PACKAGE_PREFIX}-python-setuptools")
+options=('!strip')
+source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_pyname}-${pkgver}.tar.gz")
+sha256sums=('8712034eabbfa6805cacf1402b4eeb2a73028f72d1166d6f5cb7f9c047c5d1e1')
+
+build() {
+  cp -r "${_pyname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
+
+  python -m build --wheel --skip-dependency-check --no-isolation
+}
+
+package() {
+  cd "python-build-${MSYSTEM}"
+
+  MSYS2_ARG_CONV_EXCL="--prefix=" \
+    python -m installer --prefix=${MINGW_PREFIX} \
+    --destdir="${pkgdir}" dist/*.whl
+
+  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
+}