add double-conversion (version 3.0.0) (#4310)

* add double-conversion (version 3.0.0)

* fix platform condition in patch

mingw-w64-double-conversion/PKGBUILD

@@ -0,0 +1,66 @@
+# Maintainer: Andrew Sun <adsun701@gmail.com>
+
+_realname=double-conversion
+pkgbase=mingw-w64-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
+pkgver=3.0.0
+pkgrel=1
+pkgdesc="Binary-decimal and decimal-binary routines for IEEE doubles (mingw-w64)"
+arch=('any')
+url="https://github.com/google/double-conversion"
+license=('BSD')
+depends=("${MINGW_PACKAGE_PREFIX}-gcc-libs")
+makedepends=("${MINGW_PACKAGE_PREFIX}-cmake")
+options=('strip' 'staticlibs')
+source=("${_realname}-${pkgver}.tar.gz::https://github.com/google/double-conversion/archive/v${pkgver}.tar.gz"
+        "fix-cmake-directory.patch")
+sha256sums=('152f15355242b6b1fbb4098fcd825bf08527eda0c65e8446939222a13f0b3915'
+            'a4f2cf14eaa6d49b351e05be55c9da35e4bacc02b9a6269ba17e6bfac2979b9d')
+
+prepare() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+  patch -Np1 -i "${srcdir}/fix-cmake-directory.patch"
+}
+
+build() {
+  # shared
+  [[ -d "${srcdir}"/build-${CARCH}-shared ]] && rm -rf "${srcdir}"/build-${CARCH}-shared
+  mkdir -p "${srcdir}"/build-${CARCH}-shared && cd "${srcdir}"/build-${CARCH}-shared
+
+  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
+    ${MINGW_PREFIX}/bin/cmake \
+      -G'MSYS Makefiles' \
+      -DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \
+      -DCMAKE_BUILD_TYPE=Release \
+      -DBUILD_SHARED_LIBS=ON \
+      ../${_realname}-${pkgver}
+
+  make
+
+  # static
+  [[ -d "${srcdir}"/build-${CARCH}-static ]] && rm -rf "${srcdir}"/build-${CARCH}-static
+  mkdir -p "${srcdir}"/build-${CARCH}-static && cd "${srcdir}"/build-${CARCH}-static
+
+  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
+    ${MINGW_PREFIX}/bin/cmake \
+      -G'MSYS Makefiles' \
+      -DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \
+      -DCMAKE_BUILD_TYPE=Release \
+      -DBUILD_SHARED_LIBS=OFF \
+      ../${_realname}-${pkgver}
+
+  make
+}
+
+package() {
+  # shared
+  cd "${srcdir}"/build-${CARCH}-shared
+  make install DESTDIR="${pkgdir}"
+
+  # static
+  cd "${srcdir}"/build-${CARCH}-static
+  make install DESTDIR="${pkgdir}"
+
+  # License
+  install -Dm644 ${srcdir}/${_realname}-${pkgver}/LICENSE ${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE
+}

mingw-w64-double-conversion/fix-cmake-directory.patch

@@ -0,0 +1,12 @@
+diff -Naur double-conversion-3.0.0.orig/CMakeLists.txt double-conversion-3.0.0/CMakeLists.txt
+--- double-conversion-3.0.0.orig/CMakeLists.txt	2018-08-26 06:55:18.435463000 -0400
++++ double-conversion-3.0.0/CMakeLists.txt	2018-08-26 06:55:48.450405800 -0400
+@@ -12,7 +12,7 @@
+   ${double-conversion_SOVERSION_MAJOR}.${double-conversion_SOVERSION_MINOR}.${double-conversion_SOVERSION_PATCH})
+ 
+ # set suffix for CMake files used for packaging
+-if(WIN32 AND NOT CYGWIN)
++if(MSVC)
+   set(INSTALL_CMAKE_DIR CMake)
+ else()
+   set(INSTALL_CMAKE_DIR ${CMAKE_INSTALL_LIBDIR}/cmake/double-conversion)