Add gcab

mingw-w64-gcab/PKGBUILD

@@ -0,0 +1,54 @@
+# Maintainer: Christoph Reiter <reiter.christoph@gmail.com>
+
+_realname=gcab
+pkgbase=mingw-w64-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
+pkgver=1.4
+pkgrel=1
+pkgdesc="A GObject library to create cabinet files (mingw-w64)"
+arch=('any')
+url='https://wiki.gnome.org/msitools'
+license=('LGPL')
+makedepends=("${MINGW_PACKAGE_PREFIX}-meson"
+             "${MINGW_PACKAGE_PREFIX}-ninja"
+             "${MINGW_PACKAGE_PREFIX}-vala"
+             "${MINGW_PACKAGE_PREFIX}-gobject-introspection"
+             "${MINGW_PACKAGE_PREFIX}-pkg-config")
+source=("https://download.gnome.org/sources/${_realname}/${pkgver:0:3}/${_realname}-${pkgver}.tar.xz")
+sha256sums=('67a5fa9be6c923fbc9197de6332f36f69a33dadc9016a2b207859246711c048f')
+
+prepare() {
+  cd "${srcdir}"/${_realname}-${pkgver}
+
+}
+
+build() {
+  [[ -d build-${MINGW_CHOST} ]] && rm -rf build-${MINGW_CHOST}
+  mkdir -p build-${MINGW_CHOST} && cd build-${MINGW_CHOST}
+
+  LDFLAGS+=" -lssp"
+  MSYS2_ARG_CONV_EXCL="--prefix=" \
+  meson \
+    --prefix="${MINGW_PREFIX}" \
+    --wrap-mode=nodownload \
+    --auto-features=enabled \
+    --buildtype=plain \
+    -Ddocs=false \
+    ../${_realname}-${pkgver}
+
+  meson compile
+}
+
+check() {
+  cd "${srcdir}/build-${MINGW_CHOST}"
+
+  meson test
+}
+
+package() {
+  cd "${srcdir}/build-${MINGW_CHOST}"
+
+  DESTDIR="${pkgdir}" meson install
+
+  install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING"
+}