Added mingw-w64-python-conan

mingw-w64-python-conan/0001-Loosened-node-semver-version-requirement.patch

@@ -0,0 +1,25 @@
+From d0b8e7d8bf7a051ec82c4a87d51d6bd6935482b2 Mon Sep 17 00:00:00 2001
+From: Joel Holdsworth <jholdsworth@nvidia.com>
+Date: Tue, 2 Aug 2022 13:56:53 +0100
+Subject: [PATCH] Loosened node-semver version requirement
+
+---
+ conans/requirements.txt | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/conans/requirements.txt b/conans/requirements.txt
+index e433e5cf0..066eec440 100644
+--- a/conans/requirements.txt
++++ b/conans/requirements.txt
+@@ -5,7 +5,7 @@ PyYAML>=3.11, <=6.0
+ patch-ng>=1.17.4, <1.18
+ fasteners>=0.14.1
+ six>=1.10.0,<=1.16.0
+-node-semver==0.6.1
++node-semver>=0.6.1
+ distro>=1.0.2, <=1.6.0; sys_platform == 'linux' or sys_platform == 'linux2'
+ pygments>=2.0, <3.0
+ tqdm>=4.28.1, <5
+-- 
+2.35.GIT
+

mingw-w64-python-conan/PKGBUILD

@@ -0,0 +1,61 @@
+# Maintainer: Joel Holdsworth <jholdsworth@nvidia.com>
+
+_realname=conan
+pkgbase=mingw-w64-python-conan
+pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
+provides=("${MINGW_PACKAGE_PREFIX}-python3-${_realname}")
+conflicts=("${MINGW_PACKAGE_PREFIX}-python3-${_realname}")
+replaces=("${MINGW_PACKAGE_PREFIX}-python3-${_realname}")
+pkgver=1.51.0
+pkgrel=1
+pkgdesc="A distributed, open source, C/C++ package manager (mingw-w64)"
+arch=('any')
+mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32' 'clangarm64')
+license=('spdx:MIT')
+url="https://conan.io"
+depends=("${MINGW_PACKAGE_PREFIX}-python"
+         "${MINGW_PACKAGE_PREFIX}-python-pyjwt>=1.4.0"
+         "${MINGW_PACKAGE_PREFIX}-python-requests>=2.25"
+         "${MINGW_PACKAGE_PREFIX}-python-urllib3>=1.26.6"
+         "${MINGW_PACKAGE_PREFIX}-python-colorama>=0.3.3"
+         "${MINGW_PACKAGE_PREFIX}-python-yaml>=3.11"
+         "${MINGW_PACKAGE_PREFIX}-python-patch-ng>=1.17.4"
+         "${MINGW_PACKAGE_PREFIX}-python-fasteners>=0.14.1"
+         "${MINGW_PACKAGE_PREFIX}-python-six>=1.10.0"
+         "${MINGW_PACKAGE_PREFIX}-python-node-semver>=0.6.1"
+         "${MINGW_PACKAGE_PREFIX}-python-distro>=1.0.2"
+         "${MINGW_PACKAGE_PREFIX}-python-pygments>=2.0"
+         "${MINGW_PACKAGE_PREFIX}-python-tqdm>=4.28.1"
+         "${MINGW_PACKAGE_PREFIX}-python-jinja>=3.0"
+         "${MINGW_PACKAGE_PREFIX}-python-dateutil>=2.7.0"
+         "${MINGW_PACKAGE_PREFIX}-python-bottle>=0.12.8"
+         "${MINGW_PACKAGE_PREFIX}-python-pluginbase>=0.5")
+makedepends=("${MINGW_PACKAGE_PREFIX}-python-setuptools")
+options=('staticlibs')
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/conan-io/conan/archive/${pkgver}.tar.gz"
+        "0001-Loosened-node-semver-version-requirement.patch")
+sha256sums=('1ac3d7075dfd74514e348a94f53e480f75847ada037dfbea058f28c85b58e823'
+            '116ffda81204699ea3dfdbbf471071e1a8c8dfcc17d2be970fe5e98d6657e377')
+
+prepare() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+
+  # Apply patches
+  patch -Nbp1 -i "${srcdir}/0001-Loosened-node-semver-version-requirement.patch"
+}
+
+build() {
+  msg "Python build for ${MSYSTEM}"
+  cd "${srcdir}/${_realname}-${pkgver}"
+  ${MINGW_PREFIX}/bin/python setup.py build
+}
+
+package() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
+   ${MINGW_PREFIX}/bin/python setup.py install --prefix=${MINGW_PREFIX} \
+    --root="${pkgdir}" --optimize=1 --skip-build
+
+  install -Dm644 LICENSE.md "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/COPYING"
+  install -Dm644 contributors.txt "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/contributors.txt"
+}