soapysdr: Add version 0.8.1

mingw-w64-soapysdr/001-cmake-install-path.patch

@@ -0,0 +1,15 @@
+--- src/SoapySDR-soapy-sdr-0.8.1/CMakeLists.txt.bak	2023-06-05 07:55:18.018435100 +0200
++++ src/SoapySDR-soapy-sdr-0.8.1/CMakeLists.txt	2023-06-05 07:50:42.058059500 +0200
+@@ -108,11 +108,7 @@
+ # Install cmake helper modules
+ ########################################################################
+ include(CMakePackageConfigHelpers)
+-if (UNIX)
+-    set(CMAKE_LIB_DEST ${CMAKE_INSTALL_DATADIR}/cmake/${PROJECT_NAME})
+-elseif (WIN32)
+-    set(CMAKE_LIB_DEST cmake)
+-endif ()
++set(CMAKE_LIB_DEST ${CMAKE_INSTALL_DATADIR}/cmake/${PROJECT_NAME})
+ 
+ write_basic_package_version_file(
+     ${PROJECT_BINARY_DIR}/SoapySDRConfigVersion.cmake

mingw-w64-soapysdr/PKGBUILD

@@ -0,0 +1,56 @@
+_realname=soapysdr
+_pkgname=SoapySDR
+pkgbase=mingw-w64-${_realname}
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+pkgver=0.8.1
+_gitver=soapy-sdr-$pkgver
+pkgrel=1
+pkgdesc="Vendor and platform neutral SDR support library (mingw-w64)"
+arch=('any')
+mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32' 'clangarm64')
+url="https://github.com/pothosware/SoapySDR"
+license=('Boost')
+depends=("${MINGW_PACKAGE_PREFIX}-gcc-libs"
+         "${MINGW_PACKAGE_PREFIX}-libwinpthread")
+makedepends=("${MINGW_PACKAGE_PREFIX}-cmake"
+             "${MINGW_PACKAGE_PREFIX}-ninja"
+             "${MINGW_PACKAGE_PREFIX}-cc"
+             "${MINGW_PACKAGE_PREFIX}-python")
+source=($pkgname-$pkgver.tar.gz::$url/archive/$_gitver.tar.gz
+        001-cmake-install-path.patch)
+sha256sums=('a508083875ed75d1090c24f88abef9895ad65f0f1b54e96d74094478f0c400e6'
+            '110c55a27efac2375a72a9140b21d6d41faf744951efb624db64b7854bfa8a80')
+
+prepare() {
+  cd "${srcdir}"/$_pkgname-$_gitver
+
+  patch -Np2 -i "${srcdir}"/001-cmake-install-path.patch
+}
+
+build() {
+  cd "${srcdir}"/$_pkgname-$_gitver
+
+  mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"
+
+  declare -a extra_config
+  if check_option "debug" "n"; then
+    extra_config+=("-DCMAKE_BUILD_TYPE=Release")
+  else
+    extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
+  fi
+
+  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
+    "${MINGW_PREFIX}"/bin/cmake.exe \
+      -DCMAKE_INSTALL_PREFIX="${MINGW_PREFIX}" \
+      "${extra_config[@]}" \
+      -GNinja \
+      ../$_pkgname-$_gitver
+
+  "${MINGW_PREFIX}"/bin/cmake.exe --build .
+}
+
+package() {
+  cd "${srcdir}/build-${MSYSTEM}"
+
+  DESTDIR="${pkgdir}" "${MINGW_PREFIX}"/bin/cmake.exe --install .
+}