desktop-file-utils: new package. (#2388)

mingw-w64-desktop-file-utils/001-win.patch

@@ -0,0 +1,19 @@
+--- ./Makefile.am.orig	2012-08-27 16:09:02.000000000 +0200
++++ ./Makefile.am	2015-09-28 12:33:14.881629000 +0200
+@@ -1,4 +1,4 @@
+-SUBDIRS = src man misc
++SUBDIRS = src misc
+ 
+ ACLOCAL_AMFLAGS = -I m4 ${ACLOCAL_FLAGS}
+ 
+--- ./src/update-desktop-database.c.orig	2013-01-07 08:59:20.000000000 +0100
++++ ./src/update-desktop-database.c	2015-09-28 12:33:56.081480800 +0200
+@@ -278,7 +278,7 @@
+   mask = umask(0);
+   (void) umask (mask);
+ 
+-  fchmod (fd, 0666 & ~mask);
++  //fchmod (fd, 0666 & ~mask);
+ 
+   fp = fdopen (fd, "w+");
+   if (fp == NULL)

mingw-w64-desktop-file-utils/PKGBUILD

@@ -0,0 +1,52 @@
+# Maintainer: Andrea Zagli <andrea.zagli.free@gmail.com>
+
+_realname=desktop-file-utils
+pkgbase=mingw-w64-${_realname}
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+pkgver=0.23
+pkgrel=1
+arch=('any')
+pkgdesc="Utilities for .desktop files (mingw-w64)"
+depends=("${MINGW_PACKAGE_PREFIX}-glib2"
+         "${MINGW_PACKAGE_PREFIX}-gtk3"
+         "${MINGW_PACKAGE_PREFIX}-libxml2")
+makedepends=("gtk-doc"
+             "${MINGW_PACKAGE_PREFIX}-vala"
+             "${MINGW_PACKAGE_PREFIX}-gobject-introspection"
+             "${MINGW_PACKAGE_PREFIX}-pkg-config")
+options=('!strip' 'debug' 'staticlibs')
+license=("LGPL 2.1")
+url="http://www.gnome.org/"
+source=(http://www.freedesktop.org/software/${_realname}/releases/desktop-file-utils-${pkgver}.tar.xz
+        001-win.patch)
+sha256sums=('6c094031bdec46c9f621708f919084e1cb5294e2c5b1e4c883b3e70cb8903385'
+            '477686cf08eaf80f5ee7f474cd6fb67361539f625c88fb9483ce600c5c8a73df')
+
+prepare() {
+  cd ${_realname}-${pkgver}
+
+  patch -b -V simple -p1 -i ${srcdir}/001-win.patch
+
+  autoreconf -fi
+}
+
+build() {
+  [[ -d build-${MINGW_CHOST} ]] && rm -rf build-${MINGW_CHOST}
+  mkdir -p build-${MINGW_CHOST}
+  cd build-${MINGW_CHOST}
+
+  ../${_realname}-${pkgver}/configure \
+    --host=${MINGW_CHOST} \
+    --target=${MINGW_CHOST} \
+    --build=${MINGW_CHOST} \
+    --prefix=${MINGW_PREFIX} \
+    --libexecdir=${MINGW_PREFIX}/lib
+  make
+}
+
+package() {
+  cd "$srcdir/build-${MINGW_CHOST}"
+  make DESTDIR=$pkgdir install
+
+  install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING"
+}