[new-package] glaze 4.4.3

mingw-w64-glaze/PKGBUILD

@@ -0,0 +1,47 @@
+# Maintainer: llm96 <llm96@fervidex.net>
+
+_realname=glaze
+pkgbase=mingw-w64-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
+pkgver=4.4.3
+pkgrel=1
+pkgdesc="An Extremely fast, In-Memory JSON and Interface Library for Modern C++ (mingw-w64)"
+arch=('any')
+mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
+msys2_references=(
+  'archlinux: glaze'
+)
+url="https://github.com/stephenberry/${_realname}"
+license=('spdx:MIT')
+makedepends=("${MINGW_PACKAGE_PREFIX}-cmake"
+             "${MINGW_PACKAGE_PREFIX}-ninja"
+             "${MINGW_PACKAGE_PREFIX}-cc")
+source=("$url/archive/v$pkgver/${_realname}-$pkgver.tar.gz")
+sha256sums=('d0dd03f156f95860bf9c2957da0704ee0f7651e21089ff34e3d26fa0190e8684')
+
+build() {
+  declare -a extra_config
+  if check_option "debug" "n"; then
+    extra_config+=("-DCMAKE_BUILD_TYPE=Release")
+  else
+    extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
+  fi
+
+  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
+    cmake \
+      -GNinja \
+      -DCMAKE_INSTALL_PREFIX="${MINGW_PREFIX}" \
+      "${extra_config[@]}" \
+      -Dglaze_ENABLE_FUZZING=OFF \
+      -Dglaze_DEVELOPER_MODE=OFF \
+      -S "${_realname}-${pkgver}" \
+      -B "build-${MSYSTEM}"
+
+  cmake --build "build-${MSYSTEM}"
+}
+
+package() {
+  DESTDIR="${pkgdir}" cmake --install "build-${MSYSTEM}"
+
+  install -Dm644 "${srcdir}/${_realname}-${pkgver}/LICENSE" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
+}