vmaf: Add package

mingw-w64-vmaf/PKGBUILD

@@ -0,0 +1,62 @@
+# Maintainer: Biswapriyo Nath <nathbappai@gmail.com>
+
+_realname=vmaf
+pkgbase=mingw-w64-${_realname}
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+pkgver=2.3.0
+pkgrel=1
+pkgdesc='Perceptual video quality assessment algorithm based on multi-method fusion (mingw-w64)'
+arch=('any')
+mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32')
+url='https://github.com/Netflix/vmaf/'
+license=('BSD')
+depends=("${MINGW_PACKAGE_PREFIX}-gcc-libs"
+         "${MINGW_PACKAGE_PREFIX}-libwinpthread-git")
+makedepends=("${MINGW_PACKAGE_PREFIX}-meson"
+             "${MINGW_PACKAGE_PREFIX}-nasm"
+             "${MINGW_PACKAGE_PREFIX}-pkg-config"
+             "${MINGW_PACKAGE_PREFIX}-cc")
+options=('strip' '!debug' 'staticlibs')
+source=("${_realname}-${pkgver}.tar.gz"::"https://github.com/Netflix/${_realname}/archive/v${pkgver}.tar.gz")
+sha256sums=('d8dcc83f8e9686e6855da4c33d8c373f1735d87294edbd86ed662ba2f2f89277')
+
+prepare() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+
+}
+
+build() {
+  [[ -d "${srcdir}/build-${MSYSTEM}" ]] && rm -rf "${srcdir}/build-${MSYSTEM}"
+  mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"
+
+  declare -a _extra_config
+  if check_option "debug" "n"; then
+    _extra_config+=("--buildtype=release")
+  else
+    _extra_config+=("--buildtype=debug")
+  fi
+
+  LDFLAGS+=" -lpthread" \
+  MSYS2_ARG_CONV_EXCL="--prefix=" \
+  ${MINGW_PREFIX}/bin/meson.exe \
+    --prefix="${MINGW_PREFIX}" \
+    "${_extra_config[@]}" \
+    --wrap-mode=nodownload \
+    --default-library=both \
+    --auto-features=enabled \
+    ../${_realname}-${pkgver}/libvmaf
+
+  ${MINGW_PREFIX}/bin/meson.exe compile
+}
+
+check() {
+  cd "${srcdir}/build-${MSYSTEM}"
+  ${MINGW_PREFIX}/bin/meson.exe test || true
+}
+
+package() {
+  cd "${srcdir}/build-${MSYSTEM}"
+  DESTDIR="${pkgdir}" ${MINGW_PREFIX}/bin/meson.exe install
+
+  install -Dm644 "${srcdir}/${_realname}-${pkgver}/LICENSE" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
+}