drmingw: New package.

mingw-w64-drmingw-git/PKGBUILD

@@ -0,0 +1,47 @@
+# Maintainer: Alexey Pavlov <alexpux@gmail.com>
+
+_realname=drmingw
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}-git"
+pkgver=r182.867ab17
+pkgrel=1
+pkgdesc="Just-in-Time (JIT) debugger (mingw-w64)"
+arch=('any')
+license=('GPL' 'LGPL')
+depends=("${MINGW_PACKAGE_PREFIX}-gcc-libs")
+makedepends=("${MINGW_PACKAGE_PREFIX}-cmake" "${MINGW_PACKAGE_PREFIX}-gcc")
+provides=("${MINGW_PACKAGE_PREFIX}-${_realname}")
+conflicts=("${MINGW_PACKAGE_PREFIX}-${_realname}")
+url=('https://github.com/jrfonseca/drmingw')
+source=("${_realname}"::"git+https://github.com/jrfonseca/drmingw.git")
+options=(!strip staticlibs)
+md5sums=('SKIP')
+
+pkgver() {
+  cd "$srcdir/$_realname"
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd ${_realname}
+  #patch -p1 -i ${srcdir}/build-fixes.patch
+}
+
+build() {
+  [[ -d ${srcdir}/build-${MINGW_CHOST} ]] && rm -rf ${srcdir}/build-${MINGW_CHOST}
+  mkdir -p ${srcdir}/build-${MINGW_CHOST} && cd ${srcdir}/build-${MINGW_CHOST}
+  
+  ${MINGW_PREFIX}/bin/cmake.exe \
+    -G"MSYS Makefiles" \
+    -DCMAKE_INSTALL_PREFIX:PATH=${pkgdir}${MINGW_PREFIX} \
+    ../${_realname}
+  make
+}
+
+package() {
+  cd "${srcdir}/build-${MINGW_CHOST}"
+  make -j1 install
+  rm -rf "${pkgdir}${MINGW_PREFIX}"/doc
+  rm -rf "${pkgdir}${MINGW_PREFIX}"/sample
+
+  install -Dm644 "${srcdir}/${_realname}/COPYING.LIB" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
+}