[new package] pyinstaller 6.10.0

mingw-w64-pyinstaller/PKGBUILD

@@ -0,0 +1,42 @@
+# Maintainer: Konstantin Podsvirov <konstantin@podsvirov.pro>
+
+_realname=pyinstaller
+pkgbase=mingw-w64-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
+pkgver=6.10.0
+pkgrel=1
+pkgdesc='Bundles a Python application and all its dependencies into a single package (mingw-w64)'
+arch=('any')
+mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
+url='https://pyinstaller.org/'
+msys2_repository_url='https://github.com/pyinstaller/pyinstaller'
+license=('custom')
+depends=("${MINGW_PACKAGE_PREFIX}-binutils"
+         "${MINGW_PACKAGE_PREFIX}-pyinstaller-hooks-contrib"
+         "${MINGW_PACKAGE_PREFIX}-python-altgraph"
+         "${MINGW_PACKAGE_PREFIX}-python-packaging"
+         "${MINGW_PACKAGE_PREFIX}-python-pefile"
+         "${MINGW_PACKAGE_PREFIX}-python-pywin32-ctypes"
+         "${MINGW_PACKAGE_PREFIX}-python-setuptools")
+makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
+             "${MINGW_PACKAGE_PREFIX}-python-installer"
+             "${MINGW_PACKAGE_PREFIX}-python-wheel")
+options=('!strip')
+source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
+sha256sums=('143840f8056ff7b910bf8f16f6cd92cc10a6c2680bb76d0a25d558d543d21270')
+
+build() {
+  cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
+
+  python -m build --wheel --skip-dependency-check --no-isolation
+}
+
+package() {
+  cd "python-build-${MSYSTEM}"
+
+  MSYS2_ARG_CONV_EXCL="--prefix=" \
+    python -m installer --prefix=${MINGW_PREFIX} \
+    --destdir="${pkgdir}" dist/*.whl
+
+  install -Dm644 COPYING.txt "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING.txt"
+}